I_FinancialStatementVersion

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFSVERSION'
@EndUserText.label: 'Financial Statement Version'
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@ObjectModel.representativeKey: 'FinancialStatementVariant'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: {
  serviceQuality: #A,
  sizeCategory: #S,
  dataClass: #ORGANIZATIONAL
}
@Metadata.allowExtensions:true
define view I_FinancialStatementVersion
  as select from t011
  association [1..*] to I_FinancialStatementVersionT as _Text            on $projection.FinancialStatementVariant = _Text.FinancialStatementVariant
  association [0..1] to I_ChartOfAccounts            as _ChartOfAccounts on $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
  association [1..1] to I_Language                   as _Language        on $projection.MaintenanceLanguage = _Language.Language
{
      @ObjectModel.text.association: '_Text'
  key versn as FinancialStatementVariant,
      @ObjectModel.foreignKey.association: '_Language'
      dspra as MaintenanceLanguage,
      _Language.LanguageISOCode,
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      ktopl as ChartOfAccounts,
      xergs as GroupChartOfAccountIsUsed,
      xfber as FunctionalAreaIsUsed,
      
      anhng as FinancialStatementNotesItem,
      zuord as FinancialStatementOrphansItem,
      erggv as FinStatementProfitAndLossItem,
      ergpa as FinStatementNetProfitItem,
      ergak as FinancialStatementNetLossItem,
      pssva as FinStatementLiabilitiesItem,
      aktva as FinancialStatementAssetsItem,
              
      _Text,
      _ChartOfAccounts,
      _Language
}