I_FailureModeEffectAnalysis

@AbapCatalog.sqlViewName: 'IFMEA1'    // SQL View Nanme 'IFMEA' was already in use by other CDS View and must not be used

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Failure Mode and Effects Analysis'
@ObjectModel.compositionRoot: true
@ObjectModel.representativeKey: 'FMEAHeaderUUID'
@AccessControl.privilegedAssociations:  [ '_FMEAHeaderLongText' ]
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #TRANSACTIONAL } // as function substring is used but #A and #B must not contain functions

define view I_FailureModeEffectAnalysis
  as select from plmm_audit
    inner join   I_FMEAType on plmm_audit.audit_type = I_FMEAType.FMEAType
  association [0..1] to I_FMEAHeader                as _FMEAHeader               on  $projection.FMEAHeaderUUID = _FMEAHeader.FMEAHeaderUUID
  association [0..1] to I_FMEAType                  as _FMEAType                 on  $projection.FMEAType = _FMEAType.FMEAType
  association [0..*] to I_FMEAText                  as _FMEAText                 on  $projection.FMEAHeaderUUID = _FMEAText.FMEAHeaderUUID
  association [1..*] to I_FMEANode                  as _FMEANode                 on  $projection.FMEAHeaderUUID = _FMEANode.FMEAHeaderUUID
  association [0..*] to I_FMEAPartner               as _FMEAPartner              on  $projection.FMEAHeaderUUID = _FMEAPartner.FMEAHeaderUUID
  association [0..*] to I_FMEAObject                as _FMEAObject               on  $projection.FMEAHeaderUUID = _FMEAObject.FMEAHeaderUUID
  association [0..1] to I_FMEAAuthorizationGroup    as _FMEAAuthorizationGroup   on  $projection.FMEAAuthorizationGroup = _FMEAAuthorizationGroup.FMEAAuthorizationGroup
  association [0..1] to I_FMEAStatus                as _FMEAStatus               on  $projection.FMEAStatus = _FMEAStatus.FMEAStatus
  association [0..1] to I_FMEACalculationStatus     as _FMEACalculationStatus    on  $projection.FMEACalculationStatus = _FMEACalculationStatus.FMEACalculationStatus
  association [0..1] to I_FMEAValnProcedureCombined as _FMEAValuationProcedure   on  $projection.FMEAValuationProcedure = _FMEAValuationProcedure.FMEAValuationProcedure
  association [0..1] to I_FMEARatingProfile         as _FMEARatingProfile        on  $projection.FMEARatingProfile = _FMEARatingProfile.FMEARatingProfile
  association [0..1] to I_FMEARating                as _FMEARating               on  $projection.FMEARatingProfile = _FMEARating.FMEARatingProfile
                                                                                 and $projection.FMEARating        = _FMEARating.FMEARating
  association [0..1] to I_FMEAConfidentialityLevel  as _FMEAConfidentialityLevel on  $projection.FMEAConfidentialityLevel = _FMEAConfidentialityLevel.FMEAConfidentialityLevel
  association [0..*] to I_FMEALongText              as _FMEAHeaderLongText       on  $projection.FMEAHeaderUUID = _FMEAHeaderLongText.FMEANodeUUID

  //Extension

  association [1..1] to E_FailureModeEffectAnalysis as _Extension                on  $projection.FMEAHeaderUUID = _Extension.FMEAHeaderUUID

{
  key cast( plmm_audit.guid as plmt_fmea_node_guid preserving type )               as FMEAHeaderUUID,
      plmm_audit.original_langu                                                    as OriginalLanguage,
      @ObjectModel.foreignKey.association: '_FMEAType'
      cast( plmm_audit.audit_type as plmt_tv_fmea_type preserving type )           as FMEAType,
      plmm_audit.auth_group                                                        as FMEAAuthorizationGroup,
      cast( plmm_audit.proc_status as plmt_tv_fmea_status preserving type )        as FMEAStatus,
      plmm_audit.calc_status                                                       as FMEACalculationStatus,

      case plmm_audit.changeddatetime
        when 0 then cast( '19000101010101' as tzntstmps )
        else plmm_audit.changeddatetime   end                                      as ChangedDateTime,
      plmm_audit.score_res                                                         as FMEAValuationResultValue,
      @ObjectModel.foreignKey.association: '_FMEAValuationProcedure'
      plmm_audit.audit_calculate                                                   as FMEAValuationProcedure,
      @ObjectModel.foreignKey.association: '_FMEARatingProfile'
      plmm_audit.classification                                                    as FMEARatingProfile,
      @ObjectModel.foreignKey.association: '_FMEARating'
      plmm_audit.classifi_code                                                     as FMEARating,
      plmm_audit.grouping                                                          as FMEAGroup,
      plmm_audit.search_field                                                      as FMEASearchTermValue,
      plmm_audit.header_fmea                                                       as FMEAIsHeaderFMEA,
      cast( plmm_audit.confidential as plmt_confidentialitylevel preserving type ) as FMEAConfidentialityLevel,

      //Associatons

      _FMEAHeader,
      _FMEAType,
      _FMEAText,
      _FMEANode,
      _FMEAPartner,
      _FMEAObject,
      _FMEAAuthorizationGroup,
      _FMEAStatus,
      _FMEACalculationStatus,
      _FMEAValuationProcedure,
      _FMEARatingProfile,
      _FMEARating,
      _FMEAConfidentialityLevel,
      _FMEAHeaderLongText
}