I_EntProjectPriorityCodeText

@EndUserText.label: 'Priority for Enterprise Projects - Text'

@AbapCatalog: { 
      sqlViewName: 'IENPRPRIORCODET',
      compiler.compareFilter: true,
      preserveKey: true
}

@AccessControl.authorizationCheck: #NOT_REQUIRED

@Analytics.dataExtraction.enabled: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
     representativeKey: 'PriorityCode',
     dataCategory: #TEXT,
     resultSet.sizeCategory: #XS,
     supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #LANGUAGE_DEPENDENT_TEXT, #EXTRACTION_DATA_SOURCE ],    
     usageType: {
        serviceQuality:  #A,
        dataClass:       #CUSTOMIZING,
        sizeCategory:    #S
    }
}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
define view I_EntProjectPriorityCodeText
  as select from dpr_priority_t
  association to parent I_EntProjectPriorityCode as _PriorityCode
    on $projection.PriorityCode = _PriorityCode.PriorityCode
  association [0..1] to I_Language as _Language   
    on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key language                as Language,
      @ObjectModel.foreignKey.association: '_PriorityCode'
      @ObjectModel.text.element: ['PriorityCodeName']
  key cast(lpad(cast(priority as abap.char(3)),3,'0')as abap.numc(3)) as PriorityCode,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      text                    as PriorityCodeName,
      _PriorityCode,
      _Language
}