I_EHSLocationForFiltering

@AbapCatalog:{
    sqlViewName: 'IEHSLOCFORFILTR',
    compiler.compareFilter: true,
    preserveKey: true
}
@EndUserText.label: 'EHS Location and Sublocations for Filtering'

@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
@ObjectModel:{
    representativeKey: 'EHSLocationUUID',
// used for BOBF Master Data Object

    usageType:{ serviceQuality: #C,        // < 15 msec

                         sizeCategory:  #L,         // < 10.000.000

                         dataClass: #MASTER }
}
// This returns the current sublocations of a specific location

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view I_EHSLocationForFiltering
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_Date : ehfnd_date
  as select from I_EHSLocHierarchyPath

  // get the current revision of the location hierarchy

    inner join   I_EHSLocationHierarchyRevision on  I_EHSLocationHierarchyRevision.RevisionStartDate  <= $parameters.P_Date
                                                and I_EHSLocationHierarchyRevision.RevisionEndDate    >= $parameters.P_Date
                                                and I_EHSLocHierarchyPath.EHSLocHierarchyRevisionUUID = I_EHSLocationHierarchyRevision.EHSLocHierarchyRevisionUUID

  association [1..1] to I_EHSLocationIncludingRoot  as _ParentLocation            on  _ParentLocation.RevisionStartDate <= $parameters.P_Date
                                                                                  and _ParentLocation.RevisionEndDate   >= $parameters.P_Date
                                                                                  and _ParentLocation.EHSLocationUUID   = I_EHSLocHierarchyPath.EHSParentLocationUUID
  association [1..1] to P_EHSLocationHierarchyLevel as _EHSLocationHierarchyLevel on  I_EHSLocationHierarchyRevision.EHSLocHierarchyRevisionUUID = _EHSLocationHierarchyLevel.EHSLocHierarchyRevisionUUID
                                                                                  and $projection.EHSLocationUUID                                = _EHSLocationHierarchyLevel.EHSLocationUUID
  
  association [0..*] to I_EHSLocationRevisionNameT  as _EHSLocationRevisionNameT         on  $projection.EHSParentLocationUUID     = _EHSLocationRevisionNameT.EHSLocationUUID
 
{
  key cast (I_EHSLocHierarchyPath.EHSLocationUUID as ehfnd_location_uuid_ref preserving type ) as EHSLocationUUID,
  key I_EHSLocHierarchyPath.EHSParentLocationUUID,
      _ParentLocation.EHSLocationID                                                            as EHSParentLocationID,
      _EHSLocationRevisionNameT 
}

// Add the location itself

union select from I_EHSLocationRoot
 association [0..*] to I_EHSLocationRevisionNameT  as _EHSLocationRevisionNameT         on  $projection.EHSParentLocationUUID     = _EHSLocationRevisionNameT.EHSLocationUUID
 
{
  key EHSLocationUUID,
  key EHSLocationUUID as EHSParentLocationUUID,
      EHSLocationID   as EHSParentLocationID,
      _EHSLocationRevisionNameT 
}