I_DeliveryPartnerAddress

@AbapCatalog: { 
  sqlViewName: 'IDLVPARTNERADDR',
  preserveKey: true,
  compiler.compareFilter: true
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Delivery Partner Address'

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}

@VDM.viewType: #COMPOSITE

@ObjectModel: {
  usageType.dataClass: #TRANSACTIONAL,
  usageType.serviceQuality: #C,
  usageType.sizeCategory: #L
}

define view I_DeliveryPartnerAddress as select from I_SDDocumentCompletePartners
  association [0..1] to I_DeliveryDocument as _DeliveryDocument on _DeliveryDocument.DeliveryDocument = I_SDDocumentCompletePartners.SDDocument
{
  key I_SDDocumentCompletePartners.SDDocument as DeliveryDocument,
  key I_SDDocumentCompletePartners.PartnerFunction,
  
   AddressID,
  
  ///////////////////

  // Section: Name //

  ///////////////////

  
  // Title

  _DfltAddrRprstn.FormOfAddress,
  //Name for organisation

  _DfltAddrRprstn.OrganizationName1 as BusinessPartnerName1,
  _DfltAddrRprstn.OrganizationName2 as BusinessPartnerName2,
  _DfltAddrRprstn.OrganizationName3 as BusinessPartnerName3,
  _DfltAddrRprstn.OrganizationName4 as BusinessPartnerName4,
  //Name for person

  _DfltAddrRprstn.PersonFamilyName,
  _DfltAddrRprstn.PersonGivenName,
  
  /////////////////////////////

  // Section: Street Address //

  /////////////////////////////

  
  // Buildling Code ... Room ... Floor

  _DfltAddrRprstn.Building,
  _DfltAddrRprstn.Floor,
  _DfltAddrRprstn.RoomNumber,
  
  // c/o

  _DfltAddrRprstn.CareOfName,
  
  // Street 2

  _DfltAddrRprstn.StreetPrefixName1 as StreetPrefixName,
  // Street 3

  _DfltAddrRprstn.StreetPrefixName2 as AdditionalStreetPrefixName,
  // Street ... House Number ... Suppl.

  _DfltAddrRprstn.StreetName,
  _DfltAddrRprstn.HouseNumber,
  _DfltAddrRprstn.HouseNumberSupplementText,
  // Street 4

  _DfltAddrRprstn.StreetSuffixName1 as StreetSuffixName,
  // Street 5

  _DfltAddrRprstn.StreetSuffixName2 as AdditionalStreetSuffixName,
  // District

  _DfltAddrRprstn.DistrictName as District,
  // Home City

  _DfltAddrRprstn.VillageName as HomeCityName,
  // Postal Code ... City

  _DfltAddrRprstn.PostalCode,
  _DfltAddrRprstn.CityName,
  // County

  _DfltAddrRprstn.SecondaryRegionName as County,
  // Township

  // ???

  // Country

  _DfltAddrRprstn.Country,
  // Region

  _DfltAddrRprstn.Region,
  // Time Zone ... Tax Juris.

  _DfltAddrRprstn.AddressTimeZone,
  _DfltAddrRprstn.TaxJurisdiction,
  // Transportation Zone

  _DfltAddrRprstn.TransportZone,
  // Structure Group

  // ???

  // Undeliverable

  // ???

  
  /////////////////////////////

  // Section: PO Box Address //

  /////////////////////////////

  
  // PO Box ... PO box w/o no.

  _DfltAddrRprstn.POBox,
  _DfltAddrRprstn.POBoxIsWithoutNumber,
  // Dlvry Serv/Dlvry No

  _DfltAddrRprstn.DeliveryServiceTypeCode,
  _DfltAddrRprstn.DeliveryServiceNumber,
  // PO Box Lobby

  _DfltAddrRprstn.POBoxLobbyName,
  // Postal code ... Other City

  _DfltAddrRprstn.POBoxPostalCode,
  _DfltAddrRprstn.POBoxDeviatingCityName,
  // Other Country ... Other Region

  _DfltAddrRprstn.POBoxDeviatingCountry,
  _DfltAddrRprstn.POBoxDeviatingRegion,
  // Company Postal Code

  _DfltAddrRprstn.CompanyPostalCode,
  // Undeliverable

  _DfltAddrRprstn.POBoxAddrNonDeliverableReason as AddressPostBoxUnusable,
  
  ////////////////////////////

  // Section: Communication //

  ////////////////////////////

  _DfltAddrRprstn.CorrespondenceLanguage,
  // Telephone ... Extension

  _DfltAddrRprstn._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber as PhoneNumber,
  _DfltAddrRprstn._CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber as PhoneNumberExtension,
  // Cell Phone

  _DfltAddrRprstn._CurrentDfltMobilePhoneNumber.PhoneAreaCodeSubscriberNumber as MobilePhoneNumber,
  // Fax ... Extension

  _DfltAddrRprstn._CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber as FaxNumber,
  _DfltAddrRprstn._CurrentDfltFaxNumber.FaxExtensionNumber as FaxNumberExtension,
  // E-Mail

  _DfltAddrRprstn._CurrentDfltEmailAddress.EmailAddress,
  // Standard Method

  _DfltAddrRprstn.PrfrdCommMediumType,
  // Data line

  // ???

  // Telebox

  // ???

  
  // Comments

  // ???

   
  /////////////////////////////////

  // Section: Further Attributes //

  /////////////////////////////////

  
  // Unload.Point

  // ???

  // VAT RegNo

  // ???

  _PartnerFunction,
  _DeliveryDocument
} 
  where I_SDDocumentCompletePartners.SDDocumentItem is initial and (
        _DeliveryDocument.SDDocumentCategory = 'J' or 
        _DeliveryDocument.SDDocumentCategory = '7' or 
        _DeliveryDocument.SDDocumentCategory = 'T' );