I_DefectAffectedObject

@AbapCatalog.sqlViewName: 'IDEFAFFCDOBJ'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter:true

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Object Affected by Defect'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #CHECK

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M,
        serviceQuality: #A },
    representativeKey: 'DefectAffectedObject',
    semanticKey:  [ 'Defect', 'DefectAffectedObject' ]
}
@Metadata.ignorePropagatedAnnotations: true

define view I_DefectAffectedObject as select from qmfe_affctd_obj

  association [1..1] to I_Defect        as _Defect                     on $projection.DefectInternalID = _Defect.DefectInternalID
  association [0..1] to I_Product       as _Product                    on $projection.Material = _Product.Product
  association [0..1] to I_UnitOfMeasure as _DefectAffcdObjQuantityUnit on $projection.DefectAffcdObjQuantityUnit = _DefectAffcdObjQuantityUnit.UnitOfMeasure

  // Extension

  association [1..1] to E_DefectAffectedObject as _Extension           on $projection.DefectInternalID = _Extension.Notification
                                                                      and _Extension.NotificationItem = '0000'
                                                                      and $projection.DefectAffectedObject = _Extension.DefectAffectedObject

{
      @ObjectModel.foreignKey.association: '_Defect'
  key qmnum                 as DefectInternalID,
//  key fenum not used at Defect layer

  key objcounter            as DefectAffectedObject,
  
      // Use external Defect Id as part of the semantic key

      cast( substring(qmnum,2,11) as qdefectid preserving type ) as Defect,

//    Not decided yet if they are defined as fixed domain values or if there will be a (customizing) table 

      objtype               as DefectAffectedObjectType,
      
      @ObjectModel.foreignKey.association: '_Product'
      material              as Material,
      
      @Semantics.quantity.unitOfMeasure: 'DefectAffcdObjQuantityUnit'
      quantity              as DefectAffectedObjectQuantity,
      
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_DefectAffcdObjQuantityUnit'
      quantityunit          as DefectAffcdObjQuantityUnit,
      
      batch                 as Batch,

//    Associations      

      _Defect,
      _Product,
      _DefectAffcdObjQuantityUnit

} where qmnum like '$%'
    and fenum = '0000'