I_DataExchInstructionKeysText

@AbapCatalog.sqlViewName: 'IDEINSTRNKEYT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.type: #FULL

@ClientHandling.algorithm: #SESSION_VARIABLE

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'DataExchangeInstructionKey'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M

@Search.searchable: true

@VDM.viewType: #BASIC

@EndUserText.label: 'Instruction Keys (Text)'
define view I_DataExchInstructionKeysText
  as select from t015wt
  
  association [1..1] to I_DataExchangeInstructionKeys as _InstructionKeys on  _InstructionKeys.BankCountryKey             = $projection.BankCountryKey
                                                                          and _InstructionKeys.PaymentMethod              = $projection.PaymentMethod
                                                                          and _InstructionKeys.DataExchangeInstructionKey = $projection.DataExchangeInstructionKey
  association [0..1] to I_Language                    as _Language        on  _Language.Language                          = $projection.Language                                                                   

{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key spras as Language,
      
  key banks as BankCountryKey,

  key zlsch as PaymentMethod,
  
  key dtaws as DataExchangeInstructionKey,
  
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.9  
      @Semantics.text: true
      text as DataExchInstructionKeyName,

      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _InstructionKeys,  
      _Language      
}