I_CycleRunGroup

@AbapCatalog.sqlViewName: 'IALLOCRUNGRP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Cycle Run Group'
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MASTER
}
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_CycleRunGroup
  as select from t811p
  inner join I_Ledger on t811p.org_unit = I_Ledger.Ledger
  association [0..1] to I_AllocationContextType  as _Context                on  $projection.AllocationType = _Context.AllocationType
  association [0..1] to I_AllocationPostingType  as _AllocPostingType       on  $projection.AllocationPostingType = _AllocPostingType.AllocationPostingType
  association [0..1] to I_AllocActualPlanVariant as _AllocActualPlanVariant on  $projection.AllocationActualPlanVariant = _AllocActualPlanVariant.AllocationActualPlanVariant
  association [0..1] to I_Ledger                 as _Ledger                 on  $projection.Ledger = _Ledger.Ledger  
  association [0..*] to I_CycleRunGroupText      as _Text                   on  $projection.AllocationType              = _Text.AllocationType
                                                                            and $projection.Ledger                      = _Text.Ledger
                                                                            and $projection.AllocationCycleRunGroup     = _Text.AllocationCycleRunGroup
                                                                            and $projection.AllocationPostingType       = _Text.AllocationPostingType
                                                                            and $projection.AllocationActualPlanVariant = _Text.AllocationActualPlanVariant
{
  key cast(tab as fco_allocation_context preserving type )          as AllocationType,
  key proc_group                                   as AllocationCycleRunGroup,
  key cast(alart as fco_alloc_posting_type preserving type )        as AllocationPostingType,
  key cast(ipknz as fco_alloc_ipknz preserving type )              as AllocationActualPlanVariant,
  //key cast(substring(org_unit, 1, 2) as fis_rldnr preserving type ) as Ledger,

  key cast(I_Ledger.Ledger as fis_rldnr preserving type ) as Ledger,
      _Context,
      _AllocPostingType,
      _AllocActualPlanVariant,
      _Ledger,
      _Text
}