I_CycleCountingSettings

@AbapCatalog: {
                sqlViewName: 'ICYCCOUNTSET',
                compiler.compareFilter: true,
                preserveKey: true,
                buffering : { status : #ACTIVE, type: #GENERIC, numberOfKeyFields: 2 }
              }
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Cycle Counting Settings exposed'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
                 usageType: {
                              sizeCategory: #S,
                              serviceQuality: #C,
                              dataClass:#CUSTOMIZING
                            },
                 dataCategory: #VALUE_HELP,
                 representativeKey: 'CycleCountType',
                 sapObjectNodeType: {
                                      name: 'PhysInvtryCycleCntImportance'
                                    },
                 modelingPattern: #ANALYTICAL_DIMENSION,
                 supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
               }
//@ObjectModel.resultSet.sizeCategory: #XS    "category XS lead to dropdown value help, without displaying plants

@VDM: {
        private: false,
        viewType: #BASIC
      }
@Search.searchable: true
@Consumption.ranked: true
define view I_CycleCountingSettings
  as select from t159c
{
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key werks                                                           as Plant,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key cast( abcin as mmim_cycle_count_type )                          as CycleCountType,

      cast( aninv as mmim_cycle_count_per_fisc_year )                 as NmbrOfPhysInvtryPerFiscalYear,
      cast( ininv as mmim_cycle_count_interval )                      as PhysInvtryIntvlForCycCounting,
      cast( pzinv as mmim_cycle_count_float_time )                    as PhysInvtryFloatTimeCycCounting,
      cast( configurationdeprecationcode as config_deprecation_code ) as ConfigDeprecationCode
}