I_CustomCDSViewDdicType

@AbapCatalog.sqlViewName: 'APS_CCV_I_DDICT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel : { resultSet.sizeCategory: #XS }
@EndUserText.label: 'Custom CDS View: predefined ddic type'
@ObjectModel.representativeKey: 'DdicType'
@Metadata.ignorePropagatedAnnotations:true
@VDM.viewType: #BASIC
@ObjectModel.dataCategory: #VALUE_HELP
@Search.searchable: true
define view I_CustomCDSViewDdicType as select from dd07l
    left outer join dd07t as text on  text.domname    = dd07l.domname
                                  and text.as4local   = dd07l.as4local
                                  and text.as4vers    = dd07l.as4vers
                                  and text.valpos     = dd07l.valpos
                                  and text.ddlanguage = $session.system_language
{
      @ObjectModel.text.element: ['DdicTypeText']
  key substring(dd07l.domvalue_l, 1, 10) as DdicType,
      @Search.defaultSearchElement: true
      text.ddtext                       as DdicTypeText
}
where
      dd07l.domname  = 'APS_CCV_ABAP_TYPE'
  and dd07l.as4local = 'A';