I_CustomCDSViewAuthCheck

@AbapCatalog.sqlViewName: 'APS_CCV_I_AC'
@AbapCatalog.compiler.compareFilter: true
@ObjectModel: {
  representativeKey: 'AuthorizationCheck',
  resultSet.sizeCategory: #XS
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Custom CDS View Authorization Check'
@Metadata.ignorePropagatedAnnotations:true
@VDM.viewType: #BASIC
@ObjectModel.dataCategory: #VALUE_HELP
@Search.searchable: true
define view I_CustomCDSViewAuthCheck
  as select from    dd07l
    left outer join dd07t as text on  text.domname    = dd07l.domname
                                  and text.as4local   = dd07l.as4local
                                  and text.as4vers    = dd07l.as4vers
                                  and text.valpos     = dd07l.valpos
                                  and text.ddlanguage = $session.system_language
{

      @ObjectModel.text.element: ['AuthorizationCheckText']
  key substring(dd07l.domvalue_l, 1, 1) as AuthorizationCheck,
      @Semantics.text:true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      text.ddtext                       as AuthorizationCheckText
}
where
      dd07l.domname  = 'APS_CCV_AUTHORIZATION_CHECK'
  and dd07l.as4local = 'A';