I_CustomCDSViewAnaDataCategory

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'AnalyticsDatacategory'
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.serviceQuality: #A
@AbapCatalog.sqlViewName: 'APS_CCV_I_VAD'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel : { resultSet.sizeCategory: #XS }
@EndUserText.label: 'Custom CDS View Analytics Data Category'
@Metadata.ignorePropagatedAnnotations:true
@VDM.viewType: #BASIC
@ObjectModel.dataCategory: #VALUE_HELP
@Search.searchable: true
define view I_CustomCDSViewAnaDataCategory
  as select from    dd07l
    left outer join dd07t as text on  text.domname    = dd07l.domname
                                  and text.as4local   = dd07l.as4local
                                  and text.as4vers    = dd07l.as4vers
                                  and text.valpos     = dd07l.valpos
                                  and text.ddlanguage = $session.system_language

{
      @ObjectModel.text.element: ['AnalyticsDataCategoryText']
  key substring(dd07l.domvalue_l, 1, 1) as AnalyticsDatacategory,
      @Search.defaultSearchElement: true
      text.ddtext                       as AnalyticsDataCategoryText
}
where
      dd07l.domname  = 'APS_CKGE_ANA_DATACATEG'
  and dd07l.as4local = 'A';