I_CustomCDSViewAggregation

@AbapCatalog.sqlViewName: 'APS_CCV_I_AGG'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Custom CDS View Aggregation'
@ObjectModel : { resultSet.sizeCategory: #XS }
@ObjectModel.representativeKey: 'Aggregation'
@Metadata.ignorePropagatedAnnotations:true
@VDM.viewType: #BASIC
@ObjectModel.dataCategory: #VALUE_HELP
@Search.searchable: true
define view I_CustomCDSViewAggregation
  as select from dd07l
    left outer join   dd07t as text on  text.domname    = dd07l.domname
                               and text.as4local   = dd07l.as4local
                               and text.as4vers    = dd07l.as4vers
                               and text.valpos     = dd07l.valpos
                               and text.ddlanguage = $session.system_language
{
      @ObjectModel.text.element: ['AggregationText']
  key substring(dd07l.domvalue_l, 1, 1) as Aggregation,
      @Search.defaultSearchElement: true
      text.ddtext                       as AggregationText,
      @ObjectModel: { readOnly: true, virtualElement : true,
                   filter.transformedBy: 'ABAP:CL_CCV_FILTER_AGGREG_TR_EXIT' }
      @Consumption.filter.hidden: true             
     cast('' as aps_ccv_scenario)       as CurrentScenario
}
where
      dd07l.domname  = 'APS_CCV_AGGREGATION'
  and dd07l.as4local = 'A';