I_CustMgmtIssueText

@AbapCatalog:
    {
        sqlViewName: 'ICUSTMGMTISSTXT',
        compiler.compareFilter: true,
        preserveKey: true,
        buffering: 
            { 
                status: #ACTIVE,
                type: #FULL
            }
    }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE 
@EndUserText.label: 'Text view for customer management issue'
@ObjectModel:
    {
        dataCategory: #TEXT,
        representativeKey: 'CustMgmtIssue',
        usageType:
            {
                dataClass: #META,
                serviceQuality: #A,
                sizeCategory: #S
            }
    }
@VDM.viewType: #BASIC

define view I_CustMgmtIssueText as 
    select from dd07t 

    association[0..1] to I_CustMgmtIssue as _CustMgmtIssue on $projection.CustMgmtIssue = _CustMgmtIssue.CustMgmtIssue
    association[0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_CustMgmtIssue' 
    @ObjectModel.text.element: ['CustMgmtIssueName']
    key SUBSTRING(dd07t.domvalue_l, 1, 4) as CustMgmtIssue,
    
    @Semantics.language
    @ObjectModel.foreignKey.association: '_Language' 
    key ddlanguage as Language,
    
    @Semantics.text: true
    cast( ddtext as crms4_service_issue_name )  as CustMgmtIssueName,
    
    //Associations

    _CustMgmtIssue,
    _Language
}

where domname = 'CRMS4_SERVICE_ISSUE' and as4local = 'A';