I_CurrentEHSLocHierValueHelp

@AbapCatalog.sqlViewName: 'ICURREHSLOCVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'EHS Location Value Help'

@VDM.viewType: #COMPOSITE
@ObjectModel.dataCategory:#VALUE_HELP

@ObjectModel.representativeKey: 'EHSLocationUUID'

// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec   

                         sizeCategory:  #M,         // < 100.000

                         dataClass: #MASTER } 

define view I_CurrentEHSLocHierValueHelp 
  as select from I_EHSLocation 

   // get the current revision of the location structure

  inner join I_EHSLocationHierarchyRevision on  I_EHSLocationHierarchyRevision.RevisionStartDate <= $session.system_date
                                            and I_EHSLocationHierarchyRevision.RevisionEndDate   >= $session.system_date
                                           
  inner join I_EHSLocationHierarchyNode     on I_EHSLocationHierarchyNode.EHSLocationUUID              = I_EHSLocation.EHSLocationUUID
                                            and I_EHSLocationHierarchyNode.EHSLocHierarchyRevisionUUID = I_EHSLocationHierarchyRevision.EHSLocHierarchyRevisionUUID       
                                       
  association [0..*] to I_EHSLocationTypeText  as _EHSLocationTypeText   on $projection.EHSLocationType   = _EHSLocationTypeText.EHSLocationType
   
{
  key I_EHSLocation.EHSLocationUUID,
  
  @ObjectModel.text.association: '_EHSLocationTypeText'
  cast ( EHSLocationType as ehfnd_loc_type_code_nc preserving type ) as EHSLocationType,
  
  EHSLocationStatus,
  
  Latitude,
  Longitude,
  
  EHSLocationRevisionUUID,
  
  I_EHSLocationHierarchyNode.EHSLocHierarchyNodeUUID,
  I_EHSLocationHierarchyNode.EHSParentLocationUUID,
 
  // DCL related fields

  EHSLocationAuthorizationGroup,
  Plant,
  CostCenter,
  ControllingArea,
  CompanyCode,
  BusinessArea,
  
  _EHSLocationTypeText,
  
  _EHSLocationAuthGroup,
  _Plant,
//  _CostCenter,

  _ControllingArea,
  _CompanyCode,
  _BusinessArea

} where I_EHSLocation.RevisionStartDate <= $session.system_date 
    and I_EHSLocation.RevisionEndDate   >= $session.system_date // consider current location revisions only

    and  EHSLocationStatus = '02' // consider only active locations