I_CostingSheetProcedure

@AbapCatalog.sqlViewName: 'ICOSTGSHTPROCED'
@AbapCatalog.compiler.compareFilter: true

@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@ObjectModel.representativeKey: 'CostingSheetProcedure'

@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC

@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #CUSTOMIZING

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions:true
}          
@Search.searchable: true

@EndUserText.label: 'Costing Sheet Procedure'
define view I_CostingSheetProcedure
  as select from t683

  association [0..*] to I_CostingSheetProcedureText as _Text                 on  $projection.ConditionUsage        = _Text.ConditionUsage
                                                                             and $projection.ConditionApplication  = _Text.ConditionApplication
                                                                             and $projection.CostingSheetProcedure = _Text.CostingSheetProcedure
  association [1]    to I_ConditionUsage            as _ConditionUsage       on  $projection.ConditionUsage = _ConditionUsage.ConditionUsage
  association [1]    to I_ConditionApplication      as _ConditionApplication on  $projection.ConditionApplication = _ConditionApplication.ConditionApplication
{
      @ObjectModel.foreignKey: { association: '_ConditionUsage' }
  key kvewe       as ConditionUsage,
      @ObjectModel.foreignKey: { association: '_ConditionApplication' }
  key kappl       as ConditionApplication,
      @ObjectModel.text.association: '_Text'
      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.7
      }
  key kalsm       as CostingSheetProcedure,
      @Search: {
      defaultSearchElement: true,
      ranking: #HIGH,
      fuzzinessThreshold: 0.7
      }
      @UI.hidden: true
      _Text[1:Language=$session.system_language].CostingSheetProcedureDesc,

      _Text,
      _ConditionUsage,
      _ConditionApplication

}
where
      kvewe = 'A'
  and kappl = 'KA';