I_ConditionContractStdVH

DDL: I_CONDITIONCONTRACTSTDVH Type: view COMPOSITE

Condition Contract

I_ConditionContractStdVH is a Composite CDS View that provides data about "Condition Contract" in SAP S/4HANA. It reads from 1 data source (I_ConditionContract) and exposes 21 fields with key field ConditionContract.

1 data source(s) 21 fields

Data Sources (1)

SourceAliasJoin Type
I_ConditionContract I_ConditionContract from

Annotations (19)

NameValueLevelField
AbapCatalog.sqlViewName ICNDNCNTR_SVH view
AbapCatalog.compiler.compareFilter true view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey ConditionContract view
ObjectModel.modelingPattern #VALUE_HELP_PROVIDER view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XXL view
ClientHandling.type #INHERITED view
ClientHandling.algorithm #SESSION_VARIABLE view
Analytics.internalName #LOCAL view
EndUserText.label Condition Contract view
Metadata.ignorePropagatedAnnotations true view
UI.textArrangement #TEXT_FIRST view
Search.searchable true view
Consumption.ranked true view

Fields (21)

KeyFieldSource TableSource FieldDescription
KEY ConditionContract ConditionContract
CndnContrType CndnContrType
CndnContrTypeDesc
Customer Customer
PriorSupplier PriorSupplier
Supplier Supplier
DistributionChannel DistributionChannel
Division Division
PurchasingGroup PurchasingGroup
PurchasingOrganization PurchasingOrganization
SalesOrganization SalesOrganization
PersonWorkAgreement PersonWorkAgreement
CompanyCode CompanyCode
CndnContrWorkerCostCenter CndnContrWorkerCostCenter
ExternalDocumentReferenceID ExternalDocumentReferenceID
CndnContrValidFrom CndnContrValidFrom
CndnContrValidTo CndnContrValidTo
_Customer _Customer
_PriorSupplier _PriorSupplier
_Supplier _Supplier
_PersonWorkAgreement _PersonWorkAgreement 
//GENERATED:005:GlBfhyJl7kY3iZlACiilIm

@AbapCatalog: {
  sqlViewName: 'ICNDNCNTR_SVH',
  compiler.compareFilter: true
}
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   dataCategory:          #VALUE_HELP,
   representativeKey:     'ConditionContract',
   modelingPattern:       #VALUE_HELP_PROVIDER,
   supportedCapabilities: [ #VALUE_HELP_PROVIDER, #SEARCHABLE_ENTITY],
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
@ClientHandling: {
     type: #INHERITED,
     algorithm: #SESSION_VARIABLE
}
@Analytics: {
    internalName: #LOCAL
}
@EndUserText.label: 'Condition Contract'
@Metadata.ignorePropagatedAnnotations: true
@UI.textArrangement: #TEXT_FIRST
@Search.searchable: true
@Consumption.ranked: true
define view I_ConditionContractStdVH
  as select from I_ConditionContract
{

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @UI: { lineItem: [{ position: 10, importance:#HIGH }] }
  key ConditionContract,

      @ObjectModel.text.element:  [ 'CndnContrTypeDesc' ]
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @UI: {
          lineItem:   [{ position: 20, importance:#HIGH }],
          textArrangement: #TEXT_FIRST
      }
      CndnContrType,
      @Semantics.text:true
      @Consumption.filter.hidden: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      _CndnContrType._Text[1: Language = $session.system_language ].CndnContrTypeDesc,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @UI: { lineItem: [{ position: 30, importance:#HIGH }] }
      Customer,

      @Consumption.hidden: true
      PriorSupplier,
      @Consumption.hidden: true
      Supplier,
      @Consumption.hidden: true
      DistributionChannel,
      @Consumption.hidden: true
      Division,
      @Consumption.hidden: true
      PurchasingGroup,
      @Consumption.hidden: true
      PurchasingOrganization,
      @Consumption.hidden: true
      SalesOrganization,

      /* Worker related fields */
      @Consumption.hidden: true
      PersonWorkAgreement,
      @Consumption.hidden: true
      CompanyCode,
      @Consumption.hidden: true
      CndnContrWorkerCostCenter,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #LOW
      @UI: { lineItem: [{ position: 40, importance:#HIGH }] }
      ExternalDocumentReferenceID,
      @Semantics.businessDate.from: true
      @UI: { lineItem: [{ position: 50, importance:#HIGH }] }
      CndnContrValidFrom,
      @Semantics.businessDate.to: true
      @UI: { lineItem: [{ position: 60, importance:#HIGH }] }
      CndnContrValidTo,

      @Consumption.hidden: true
      _Customer,
      @Consumption.hidden: true
      _PriorSupplier,
      @Consumption.hidden: true
      _Supplier,
      @Consumption.hidden: true
      _PersonWorkAgreement
}

Learn More