I_CntrlPurContrDistributionTP

@AbapCatalog.sqlViewName: 'ICNTRLPCONDSTRTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Central PC Distribution BO View'

@ObjectModel.writeDraftPersistence: 'CNTRLPCDISTRTP_D'
@VDM.viewType:#TRANSACTIONAL
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: 'EXTERNAL_CALCULATION'

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED

@AccessControl.personalData.blocking: #REQUIRED

define view I_CntrlPurContrDistributionTP 
  as select from I_CntrlPurContrDistribution

  association [1..1] to I_CentralPurchaseContractTP   as _CentralPurchaseContractTP   on  _CentralPurchaseContractTP.CentralPurchaseContract = $projection.CentralPurchaseContract

  association [1..1] to I_CntrlPurchaseContractItemTP as _CntrlPurchaseContractItemTP on  _CntrlPurchaseContractItemTP.CentralPurchaseContractItem = $projection.CentralPurchaseContractItem
                                                                                      and _CntrlPurchaseContractItemTP.CentralPurchaseContract     = $projection.CentralPurchaseContract

  association [0..*] to I_CntrlPurContrItemPartnerTP  as _CntrlPurContrItemPartnerTP  on  _CntrlPurContrItemPartnerTP.CentralPurchaseContract     = $projection.CentralPurchaseContract
                                                                                      and _CntrlPurContrItemPartnerTP.CentralPurchaseContractItem = $projection.CentralPurchaseContractItem
                                                                                      and _CntrlPurContrItemPartnerTP.DistributionKey             = $projection.DistributionKey

  association [0..1] to I_CntrlPurContrItmDistrAddrTP as _CntrlPurContrItmDistrAddrTP on  _CntrlPurContrItmDistrAddrTP.CentralPurchaseContract     = $projection.CentralPurchaseContract
                                                                                      and _CntrlPurContrItmDistrAddrTP.CentralPurchaseContractItem = $projection.CentralPurchaseContractItem
                                                                                      and _CntrlPurContrItmDistrAddrTP.DistributionKey             = $projection.DistributionKey
  association [0..1] to I_PurgDocumentCategoryText    as _PurgDocumentCategoryText    on  _PurgDocumentCategoryText.PurchasingDocumentCategory     = $projection.PurchasingDocumentCategory
                                                                                      and _PurgDocumentCategoryText.Language                       = $session.system_language
  
  association [0..1] to I_CntrlPurContrDistrTypeText as _CntrlPurContrDistrTypeText   on  _CntrlPurContrDistrTypeText.DistributionType = $projection.DistributionType
                                                                                      and _CntrlPurContrDistrTypeText.Language = $session.system_language

  association [0..1] to I_PaymentTerms                as _PaymentTerms                on  $projection.PaymentTerms = _PaymentTerms.PaymentTerms
  association [0..*] to I_PaymentTermsText            as _PaymentTermsText            on  $projection.PaymentTerms = _PaymentTermsText.PaymentTerms

  association [0..1] to I_Currency                    as _DocumentCurrency            on  _DocumentCurrency.Currency = $projection.Currency
 
  association [0..1] to I_ContrItmDistrEnhancedFields  as _ContrItmDistrEnhancedFields  on  $projection.CentralPurchaseContractItem = _ContrItmDistrEnhancedFields.CentralPurchaseContractItem
                                                                                        and $projection.CentralPurchaseContract     = _ContrItmDistrEnhancedFields.CentralPurchaseContract
                                                                                        and $projection.DistributionKey             = _ContrItmDistrEnhancedFields.DistributionKey
 

   ----Extension Association 
  association [1..1] to E_CntrlPurContrDistribution   as _CntrlPurContrItmDistExtension on  _CntrlPurContrItmDistExtension.PurchasingDocument     = $projection.CentralPurchaseContract
                                                                                       and _CntrlPurContrItmDistExtension.PurchasingDocumentItem   = $projection.CentralPurchaseContractItem
                                                                                       and _CntrlPurContrItmDistExtension.DistributionKey          = $projection.DistributionKey

{
  key CentralPurchaseContract,
  key CentralPurchaseContractItem,
  key DistributionKey,
      PurchasingDocumentCategory,
      PurchasingDocumentType,
      PurchasingOrganization,
      CompanyCode,
      Plant,
      LogicalSystem,      
//    Document Currency will be the Currency at CCTR item

//    Net price/Target Amount/GR Amount will be displayed in CCTR Item Currency

      _CntrlPurchaseContractItem.DocumentCurrency as DocumentCurrency,
      Currency,
      PurchasingGroup,
      StorageLocation,
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      NetPaymentDays,
      CashDiscount1Percent,
      CashDiscount2Percent,
      Material,
      MaterialGroup,
      CntrlPurContrDistributionPct,
      TargetQuantity,
      TargetAmount,
      ExtContractForPurg,
      ExtContractItemForPurg,
      ExtContractItemDistrForPurg,
//    Performance improvrment: case done at the lower level  

      ItemDistributionStatus,
      IsDeleted,
      OrderQuantityUnit,
      DistributionType,
      
      _CntrlPurchaseContractItem.ContractNetPriceAmount as ContractNetPriceAmount,
      DistrResponseMessageUUID,

      ItemDistributionIsRelevant,
      CntrlPurContrItmDistrIsBlocked,
      ReferenceHeaderDistributionKey,

      ManualDeliveryAddressID,
      AddressType, //DO NOT USE THIS FIELD BECAUSE OF DOMAIN AND GFN INCOMPATIBILITY. TO BE RESOLVED LATER

      ProcmtHubDelivAddressTypeCode,
      ProcurementHubSourceSystem, 
      ExternalReferenceDocument,
      ExternalReferenceDocumentItem,
      ExternalRefDocCategory,
      case
       when ProcmtHubPredecessorDocument <> ''
        then 'X'
       else ' '
      end as IsExtPurgScenario,
      OutlineAgrmtItmIsBlocked,
      case IsDeleted
       when 'X'
        then cast ( '' as  boolean )
       else
        cast( OutlineAgrmtItmIsBlocked as boolean )
      end as OutlineAgrmtItmBlockedText,
      case IsDeleted
       when 'X'
        then ''
       else
        PurgDocItmBlkRsnCode
      end as PurgDocItmBlkRsnCode,      
      PurchasingInfoRecordUpdateCode,
      ProcmtHubPredecessorDocument,
      ProcmtHubPredecessorDocItem,
      ProcmtHubPredecessorDocCat,
      ProcmtHubPurchaseRequisition,
      ProcmtHubPurRequisitionItem,
      
      /*sourcelist related */
      cast(SourceListIsUpdated as xfeld) as SourceListIsUpdated,
      SourceListRestriction,
      
      /* incoterms and shipping instruction*/
      IncotermsClassification,
      IncotermsLocation1,
      ShippingInstruction,
      
      // Added for Contract Hierarchy

      ProcmtHubCompanyCodeGroupingID,
      
      /* Address related fields */
      ProcmtHubSubcontractor,
      ProcmtHubSuplrIsSubcontractor,
      ReferenceDeliveryAddressID,
      FormOfAddress,
    //  ProcmtHubFormOfAddress,

      ProcmtHubBusinessPartnerName1,
      ProcmtHubBusinessPartnerName2,
      ProcmtHubBusinessPartnerName3,
      ProcmtHubBusinessPartnerName4,
      ProcmtHubStreetName,
      ProcmtHubHouseNumber,
      ProcmtHubPostalCode,
      ProcmtHubCityName,
      ProcmtHubCountry,
      ProcmtHubRegion,
      
      /* The fields with predecessor document information */
      ProcmtHubPrdcssrDocUUID,
      ProcmtHubPrdcssrDocItemUUID,
      ProcmtHubPrdcssrDocObjType,
      ProcmtHubPrdcssrDocObjNodeType,      
      
      _CntrlPurchaseContractItemTP.PurchasingDocumentItemCategory as PurchasingDocumentItemCategory,
            
      @Semantics.quantity.unitOfMeasure: 'ReleaseOrderItemQuantityUnit'
      _ContrItmDistrEnhancedFields.CntrlPurContractGRQuantity,
      _ContrItmDistrEnhancedFields.ReleaseOrderItemQuantityUnit,
      @Semantics.amount.currencyCode: 'ReleaseOrderCurrency'
      _ContrItmDistrEnhancedFields.CntrlPurContractGRAmount,
      _ContrItmDistrEnhancedFields.ReleaseOrderCurrency,

      
      _PaymentTerms,
      _PaymentTermsText,
      
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
      _CntrlPurchaseContractItemTP,

      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _CentralPurchaseContractTP,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrlPurContrItemPartnerTP,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrlPurContrItmDistrAddrTP,

      _PurgDocumentCategoryText,
      
      _CntrlPurContrDistrTypeText,
        
      _DocumentCurrency
      
}
//where IsDeleted <> 'X'