I_CmplncRqmtRsltCmplncStsTxt

@AbapCatalog.sqlViewName: 'ICRRCSTSTXT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@EndUserText.label: 'CRR Compliance Status Text'

-- CDS View Classification: 1. No data access restriction required
-- Reason: Text View for Domain Fix values
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC

@ObjectModel:
{
  --Data category
    /*
      #TEXT:      the annotated entity represents texts
      #HIERARCHY: the entity represents the hierarchy-related data
    */
  dataCategory: #TEXT,
  representativeKey: 'CmplRqRsltCmplncSts',

    --Performance Annotations
  usageType:
  {
    dataClass: #CUSTOMIZING,
    sizeCategory: #S,
    serviceQuality: #B
  }
}

@Search.searchable: true

define view I_CmplncRqmtRsltCmplncStsTxt
  as select from dd07t
  // parent-child relation of the composition is based on the Sample Fix domain value helps see https://wiki.wdf.sap.corp/wiki/display/SuiteCDS/VDM+CDS+Code+List+Views+and+Services

  association        to parent I_CmplncRqmtRsltCmplncStsVH as _CmplncRqmtRsltCmplncStsVH on $projection.CmplRqRsltCmplncSts = _CmplncRqmtRsltCmplncStsVH.CmplRqRsltCmplncSts
  association [0..1] to I_Language                         as _Language                  on $projection.Language = _Language.Language

{
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cast(ddlanguage as spras preserving type)                  as Language,

  key cast(domvalue_l as ehfnd_crr_overall_status )              as CmplRqRsltCmplncSts,

      /****  Content  ****/
      @Consumption.hidden: true
      dd07t.domvalue_l                                           as DomainValue,

      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      cast(ddtext as ehfnd_crr_compl_stat_text preserving type ) as CmplRqRsltCmplncStsTxt,

      /* Associations */
      _Language,
      _CmplncRqmtRsltCmplncStsVH
      
     
}
where
      domname  = 'EHFND_CRR_COMPSTAT'
  and as4local = 'A'
  and as4vers  = '0000'