I_ChmlSuplrMatlNames

@EndUserText.label: 'Names of Supplier Material'

@AbapCatalog:
{
  sqlViewName: 'ICSMNAME',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl:
{
  authorizationCheck: #CHECK,
  // blocking of personal data required because of link to business partner / supplier

  personalData.blocking: #REQUIRED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE

@ObjectModel:
{
  semanticKey:  [ 'ChmlSuplrMatlUUID' ],
  --Performance Annotations
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #C
  },
  representativeKey: 'ChmlSuplrMatlUUID'
}

define view I_ChmlSuplrMatlNames
  --Select data from basic view of Supplier Material
  as select from           I_ChmlSuplrMatl             as SupplierMaterial

  --join supplier material data
    left outer to one join I_ChmlCmplncSuplrMatlAssgmt as SuplrMatlAssignment on SupplierMaterial.ChmlSuplrMatlUUID = SuplrMatlAssignment.ChmlSuplrMatlUUID

  --join data of raw material
    left outer to one join C_ChmlCmplncPrimMatl        as RawMaterialData     on SuplrMatlAssignment.ChmlCmplncInfoUUID = RawMaterialData.ChmlCmplncInfoUUID

{
      --UUID of Supplier Material
  key SupplierMaterial.ChmlSuplrMatlUUID,

      ---- Supplier name ----
      SupplierMaterial.BusinessPartnerSupplier,

      ---- Supplier (external) material nummber  ----
      SupplierMaterial.SupplierMaterialNumber,

      ---- Supplier (external) material name ----
      SupplierMaterial.ChmlSuplrMatlName,

      --Concatenate the name of supplier material: "Supplier - Raw Material Name"
      cast( concat_with_space(SupplierMaterial._BusinessPartner.BusinessPartnerFullName,
        concat_with_space('-', RawMaterialData.ChmlCmplncInfoCombinedName, 1), 1) as ehfnd_csm_supplier_raw_matl )                 as SupplierMaterialCombinedName,
        
      // needed for DCL

      --Responsible Unit
      @Consumption.hidden: true
      SupplierMaterial.ResponsibleUnit,
      
      // Needed for DCL

      @Consumption.hidden: true
      SupplierMaterial._BusinessPartnerSupplier.AuthorizationGroup,
      
      // Associations

      SupplierMaterial._ResponsibleUnit,
      SupplierMaterial._BusinessPartner

}