I_ChmlSuplrMatlImprtRespy

@AbapCatalog.sqlViewName: 'ICHMLSUPLSPY'
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@AccessControl:{
  authorizationCheck: #CHECK,
  privilegedAssociations: ['_CreatedByUser','_LastChangedByUser']
}

@EndUserText.label: 'Supplier Material Import Responsibility'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel:{
  usageType:{
  serviceQuality: #B,
  sizeCategory: #L,
  dataClass: #MASTER
  },
    semanticKey:  [ 'ImprtRespyBuyingCompanyCode',
                    'ImprtRespyRcvgPlant' ] }

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
define view I_ChmlSuplrMatlImprtRespy
  as select from ehfndv_csm_iresp as ImportResponsibility
  -- Supplier Material
  association [1..1] to I_ChmlSuplrMatl             as _ChmlSuplrMatl          on  $projection.ChmlSuplrMatlUUID = _ChmlSuplrMatl.ChmlSuplrMatlUUID
  -- Responsible Importer
  association [1..1] to I_ImprtRespyRespImporter    as _ResponsibleImporter    on  $projection.ImprtRespyRespImporter = _ResponsibleImporter.ImprtRespyRespImporter
  association [0..*] to I_ImprtRespyRespImporterTxt as _ResponsibleImporterTxt on  $projection.ImprtRespyRespImporter = _ResponsibleImporterTxt.ImprtRespyRespImporter
  -- Plant
  association [1..1] to I_Plant                     as _ReceivingPlantDetails  on  $projection.ImprtRespyRcvgPlant = _ReceivingPlantDetails.Plant                                                                             
  -- Company Code
  association [1..1] to I_CompanyCode               as _BuyingCompany          on  $projection.ImprtRespyBuyingCompanyCode = _BuyingCompany.CompanyCode
  -- Admin fields
  association [0..1] to I_User                      as _CreatedByUser          on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                      as _LastChangedByUser      on  $projection.LastChangedByUser = _LastChangedByUser.UserID
{
      --UUID of Import Responsibility
  key ImportResponsibility.chmlsuplrmatlimprtrespyuuid as ChmlSuplrMatlImprtRespyUUID,

      --Create date/time
      @Semantics.systemDateTime.createdAt: true
      ImportResponsibility.creationutcdatetime         as CreationUTCDateTime,

      --Created by user
      @Semantics.user.createdBy: true
      @ObjectModel.readOnly: true
      ImportResponsibility.createdbyuser               as CreatedByUser,

      --Change date/time
      @Semantics.systemDateTime.lastChangedAt: true
      ImportResponsibility.lastchangeutcdatetime       as LastChangeUTCDateTime,

      --Changed by user
      @Semantics.user.lastChangedBy: true
      @ObjectModel.readOnly: true
      ImportResponsibility.lastchangedbyuser           as LastChangedByUser,

      --UUID of Supplier Material
      ImportResponsibility.chmlsuplrmatluuid           as ChmlSuplrMatlUUID,

      --Buying Comapny Code
      ImportResponsibility.imprtrespybuyingcompanycode as ImprtRespyBuyingCompanyCode,

      --Receiving Plant
      ImportResponsibility.imprtrespyrcvgplant         as ImprtRespyRcvgPlant,

      --Responsible Importer
      ImportResponsibility.imprtrespyrespimporter      as ImprtRespyRespImporter,

      -- Valid from date of setting
      ImportResponsibility.validitystartdate           as ValidityStartDate,

      --Valid to date of setting
      ImportResponsibility.validityenddate             as ValidityEndDate,

      --Remark
      ImportResponsibility.imprtrespyremarktext        as ImprtRespyRemarkText,

      /* Associations */
      _ChmlSuplrMatl,
      _ResponsibleImporter,
      _ResponsibleImporterTxt,
      _ReceivingPlantDetails,
      _BuyingCompany,
      _CreatedByUser,
      _LastChangedByUser
}