I_ChmlSuplrMatlComponentTP

@EndUserText.label: 'Supplier Material Component'

@AbapCatalog:
{
  sqlViewName: 'ICSUPMATCMPTP',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl:
{
  --TODO Chemical Compliance - Authority Check for Composition?
  authorizationCheck: #CHECK
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel:
{
  --Transactional Annotations for the generated BO
  modelCategory: #BUSINESS_OBJECT,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  writeDraftPersistence: 'EHFNDW_CSM_CMP',
  writeActivePersistence: 'EHFNDV_CCMPS_CMP',
  semanticKey:  [ 'ChmlCompUUID' ],
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #XL,
    serviceQuality: #C
  }
}

define view I_ChmlSuplrMatlComponentTP 
  --Select data from basic view 'Chemical Component'
  as select from I_ChmlComponent as Component

  --Nodes/Detaildata;
  -- Supplier Material
  association [1..1] to I_ChmlSuplrMatlTP as _ChmlSuplrMatl on $projection.ChmlSuplrMatlUUID = _ChmlSuplrMatl.ChmlSuplrMatlUUID

{
      --UUID of component
      @ObjectModel.mandatory: true
  key Component.ChmlCompUUID,

      --Active UUID of chemical component
      Component.ChmlCompUUID as ActiveChmlCompUUID,
      
      --UUID of Supplier Material
      Component.ChmlSuplrMatlUUID,
      
      --UUID of chemical composition
      Component.ChmlCompositionUUID,
      
      --Date/Time of creation
      @ObjectModel.readOnly: true
      Component.CreationUTCDateTime,

      --Created by
      @ObjectModel.readOnly: true
      Component.CreatedByUser,

      --Date/Time of change
      @ObjectModel.readOnly: true
      Component.LastChangeUTCDateTime,

      --Changed by
      @ObjectModel.readOnly: true
      Component.LastChangedByUser,      
      
      --UUID of Substance
      @ObjectModel.mandatory: true
      Component.SubstanceUUID,
      
      --Component Type
      @ObjectModel.mandatory: true
      Component.ChmlCompType,

      --Concentration of component
      Component.ChmlCompQty,

      --Unit of measurment of concentration
      Component.ChmlCompQtyUnit,

      --Lower limit of concentration
      Component.ChmlCompQtyLowerLimit,

      --Upper limit of concentration
      Component.ChmlCompQtyUpperLimit,

      /* Associations */
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ChmlSuplrMatl,
      
      _Substance,

      _ComponentType,
      _UnitOfMeasure
}