I_ChmlComponentOptrUprLmt

--Label of view
@EndUserText.label: 'Operator of Upper Limit'

@AbapCatalog:
{
  -- SQL view name (16 characters)
  sqlViewName: 'ICCCMPOPUPR',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true
}

--Access Control: Authorizations Checks
@AccessControl:
{
  // authorization check not required as view only reads domain values

  authorizationCheck: #NOT_REQUIRED
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

--VDM view type
@VDM.viewType: #BASIC

@ObjectModel:
{
  resultSet.sizeCategory: #XS,

  --Performance Annotations
  usageType:
  {
    dataClass: #META,
    sizeCategory: #S,
    serviceQuality: #B
  },
  representativeKey: 'ChmlCompOperatorUpperLimit'
}
define view I_ChmlComponentOptrUprLmt
  --Select data from domain value table
  as select from dd07l

  --Text association
  association [0..*] to I_ChmlComponentOptrUprLmtT as _Text on $projection.ChmlCompOperatorUpperLimit = _Text.ChmlCompOperatorUpperLimit
{
      --Domain Value of Operator of Upper Limit
      @ObjectModel.text.association: '_Text'
  key substring(domvalue_l, 1, 5) as ChmlCompOperatorUpperLimit,

      /*Association*/
      _Text
}
where
      domname  = 'EHFND_CCI_CCOMP_UPPER_OPERATOR'
  and as4local = 'A'