I_ChmlCmpstnUnitOfMeasureVH

--Label of view
@EndUserText.label: 'Unit of measure value help for compositions'

@Search.searchable: true
@AbapCatalog:
{
  -- SQL view name (16 characters)
  sqlViewName: 'ICCMPNUOMVH',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true,
  preserveKey: true
}

--Access Control: Authorizations Checks
@AccessControl:
{
  // authorization check not required as view only reads domain values

  authorizationCheck: #NOT_REQUIRED
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE

@ObjectModel:
{
  dataCategory: #VALUE_HELP,
  --Value help as DropDown
  resultSet.sizeCategory: #XS,

  --Performance Annotations
  usageType:
  {
    dataClass: #CUSTOMIZING,
    sizeCategory: #S,
    serviceQuality: #B
  }
}

@Metadata.ignorePropagatedAnnotations: true

-- SortOrder: largest unit first, smallest as last
@UI.presentationVariant: [{ sortOrder: [{by: 'SIUnitCnvrsnRateExponent', direction: #DESC}] }]

define view I_ChmlCmpstnUnitOfMeasureVH
  as select from I_UnitOfMeasure

  association [0..*] to I_UnitOfMeasureText as _Text on $projection.UnitOfMeasure = _Text.UnitOfMeasure

{
      @ObjectModel.text.element:  [ 'UnitOfMeasureName' ]
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
  key cast ( I_UnitOfMeasure.UnitOfMeasure as ehfnd_unit_code_meins preserving type ) as UnitOfMeasure,

      --Description of Status
      @UI.hidden: true
      @Semantics.text: true
      _Text[1: Language = $session.system_language ].UnitOfMeasureName,
      
      SIUnitCnvrsnRateExponent
}
where
     UnitOfMeasure = '%'
  or UnitOfMeasure = 'PPM'
  or UnitOfMeasure = 'PPB'
  or UnitOfMeasure = 'PPT'