I_ChmlCmplncReqSlsOrg

@EndUserText.label:  'Chemical Compliance Request Sales Organization'

@AbapCatalog:
{
  sqlViewName: 'ICRQVKORG',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY
}

@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  }
}

@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_ChmlCmplncReqSlsOrg
  as select from ehfndv_crq_vkorg
  association [1..1] to I_SalesOrganization as _SalesOrganization on $projection.SalesOrganization = _SalesOrganization.SalesOrganization
  association [1..1] to I_ChmlCmplncReq     as _ChmlCmplncReq     on $projection.ChmlCmplncRequestUUID = _ChmlCmplncReq.ChmlCmplncRequestUUID
{

  key chmlcmplncreqsalesorguuid                                               as ChmlCmplncReqSalesOrgUUID,
      chmlcmplncrequestuuid                                                   as ChmlCmplncRequestUUID,

      @Semantics.systemDateTime.createdAt: true
      cast(creationutcdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationUTCDateTime,
      @Semantics.user.createdBy: true
      cast(createdbyuser as ehfnd_bo_crea_uname preserving type )             as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeUTCDateTime,
      @Semantics.user.lastChangedBy: true
      cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )         as LastChangedByUser,

      salesorganization                                                       as SalesOrganization,
      distributionchannel                                                     as DistributionChannel,

      chmlcmplncreqchgtype                                                    as ChmlCmplncReqChgType,

      _SalesOrganization,

      _ChmlCmplncReq
}