I_ChmlCmplncReqRouteSegment

@EndUserText.label: 'Chemical Compliance Request Route Segment'

@AbapCatalog:
{
  sqlViewName: 'ICRQRS',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  privilegedAssociations: ['_CreatedByUser','_LastChangedByUser']
}

@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  }
}

@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_ChmlCmplncReqRouteSegment
  as select from ehfndv_crq_rs
  association [1..1] to I_ChmlCmplncReq as _ChmlCmplncReq on $projection.ChmlCmplncRequestUUID = _ChmlCmplncReq.ChmlCmplncRequestUUID
  
  association [0..1] to I_User          as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User          as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [1..1] to I_Country       as _Country           on $projection.RouteSegmentCountry = _Country.Country
  
{

  key chmlcmplncroutesegmentuuid                                              as ChmlCmplncRouteSegmentUUID,
      chmlcmplncrequestuuid                                                   as ChmlCmplncRequestUUID,

      @Semantics.systemDateTime.createdAt: true
      cast(creationutcdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationUTCDateTime,
      @Semantics.user.createdBy: true
      cast(createdbyuser as ehfnd_bo_crea_uname preserving type )             as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeUTCDateTime,
      @Semantics.user.lastChangedBy: true
      cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )         as LastChangedByUser,

      routesegmentcountry                                                     as RouteSegmentCountry,
      dngrsgoodsmodeoftransport                                               as DngrsGoodsModeOfTransport,

      _ChmlCmplncReq,
      
      _CreatedByUser,
      _LastChangedByUser,
      _Country

}