I_ChmlCmplncReqPlnt

@EndUserText.label: 'Chemical Compliance Request Plant'

@AbapCatalog:
{
  sqlViewName: 'ICRQPLNT',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY
}

@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  }
}

@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_ChmlCmplncReqPlnt
  as select from ehfndv_crq_plant
  association [0..1] to I_Plant         as _Plant         on $projection.ActivePlant = _Plant.Plant
  association [1..1] to I_ChmlCmplncReq as _ChmlCmplncReq on $projection.ChmlCmplncRequestUUID = _ChmlCmplncReq.ChmlCmplncRequestUUID
{

  key chmlcmplncreqplntuuid                                                   as ChmlCmplncReqPlntUUID,
      chmlcmplncrequestuuid                                                   as ChmlCmplncRequestUUID,

      @Semantics.systemDateTime.createdAt: true
      cast(creationutcdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationUTCDateTime,
      @Semantics.user.createdBy: true
      cast(createdbyuser as ehfnd_bo_crea_uname preserving type )             as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeUTCDateTime,
      @Semantics.user.lastChangedBy: true
      cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )         as LastChangedByUser,

      activeplant                                                             as ActivePlant,

      chmlcmplncreqchgtype                                                    as ChmlCmplncReqChgType,
      
      _Plant,
      _ChmlCmplncReq
}