I_ChmlCmplncMktCvrg

@EndUserText.label: 'Chemical Compliance Market Coverage'

@AbapCatalog:
{
  sqlViewName: 'ICCMKTCOV',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #CHECK,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}

@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  }
}

@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_ChmlCmplncMktCvrg
  as select from ehfndv_cci_mcvrg
  association [1..1] to I_ChmlCmplncInfo as _ChmlCmplncInfo    on _ChmlCmplncInfo.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID
  association [0..1] to I_User           as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User           as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [1..1] to I_Country        as _Country           on $projection.Country = _Country.Country

{
  key chmlcmplncmktcvrguuid                                                   as ChmlCmplncMktCvrgUUID,
      chmlcmplncinfouuid                                                      as ChmlCmplncInfoUUID,

      chmlcmplncmktrequuid                                                    as ChmlCmplncMktReqUUID,

      @Semantics.systemDateTime.createdAt: true
      cast(creationutcdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationUTCDateTime,
      @Semantics.user.createdBy: true
      cast(createdbyuser as ehfnd_bo_crea_uname preserving type )             as CreatedByUser,

      @Semantics.systemDateTime.lastChangedAt: true
      cast(lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeUTCDateTime,

      @Semantics.user.lastChangedBy: true
      cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )         as LastChangedByUser,

      @ObjectModel.foreignKey.association: '_Country'
      country                                                                 as Country,
      chmlcmplncprodnallwd                                                    as ChmlCmplncProdnAllwd,
      chmlcmplncexprtallwd                                                    as ChmlCmplncExprtAllwd,
      chmlcmplncimprtallwd                                                    as ChmlCmplncImprtAllwd,
      chmlcmplncsalesallwd                                                    as ChmlCmplncSalesAllwd,

      chmlcmplncmktcvrgremark                                                 as ChmlCmplncMktCvrgRemark,

      -- associations
      _ChmlCmplncInfo,
      _CreatedByUser,
      _LastChangedByUser,
      _Country
}