I_ChmlCmplncInfoActiveDraft

--Label of view
@EndUserText.label: 'Chemical Compliance Information with active and draft data'

@AbapCatalog:
{
  -- SQL view name (16 characters)
  sqlViewName: 'ICCIADR',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true,
  preserveKey: true
}

--Access Control: Authorizations Checks
@AccessControl:
{
  authorizationCheck: #CHECK
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

--VDM view type
@VDM.viewType: #COMPOSITE

@ObjectModel:
{
  --Performance Annotations
  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #C
  }
}

define view I_ChmlCmplncInfoActiveDraft
  --Select data from basic view of chemical chemical compliance information
  as select from           I_ChmlCmplncInfo      as ChemicalComplianceInfo
  --join data from draft table of chemical compliance information
    left outer to one join I_ChmlCmplncInfoDraft as ChemicalComplianceInfoDraft on  ChemicalComplianceInfo.ChmlCmplncInfoUUID     = ChemicalComplianceInfoDraft.ActiveChmlCmplncInfoUUID

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
  association [1..1] to P_ChmlCmplConstants as _Constants on _Constants.Constant1 = _Constants.Constant1
{
      --UUID of active chemical compliance information
  key ChemicalComplianceInfo.ChmlCmplncInfoUUID         as ActiveChmlCmplncInfoUUID,

      ----UUID of active or draft chemical compliance information
      case
        when ChemicalComplianceInfoDraft.ChmlCmplncInfoUUID is not null
        then ChemicalComplianceInfoDraft.ChmlCmplncInfoUUID
        else ChemicalComplianceInfo.ChmlCmplncInfoUUID
      end                                               as ChmlCmplncInfoUUID,

      --Indicator: Is Active Entity
      cast( case
              when ChemicalComplianceInfoDraft.ChmlCmplncInfoUUID is not null
              then _Constants[inner].ConstantFalse
              else _Constants[inner].ConstantTrue
            end as sdraft_is_active preserving type )   as ChmlCmplncInfoIsActiveEntity,

      // needed for DCL

      ChemicalComplianceInfo.ProdStewardshipRespUnit    as ProdStewardshipRespUnit,
      ChemicalComplianceInfo.MaterialIsSold             as MaterialIsSold,
      ChemicalComplianceInfo.MaterialIsTransported      as MaterialIsTransported,
      ChemicalComplianceInfo.MaterialIsSourced          as MaterialIsSourced,
      ChemicalComplianceInfo.MaterialIsProduced         as MaterialIsProduced,
      ChemicalComplianceInfo.MaterialIsDisposed         as MaterialIsDisposed,
      ChemicalComplianceInfo.MaterialIsEmissionRelevant as MaterialIsEmissionRelevant

}