I_ChmlCmplncAnlyts2

@AbapCatalog.sqlViewName: 'ICCMPLCNINFOA2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.representativeKey: 'Material'

@EndUserText.label: 'Dimension Product Assignment'

@AccessControl.authorizationCheck: #CHECK

@ClientHandling:
{
  type: #INHERITED,
  algorithm: #SESSION_VARIABLE
}

@ObjectModel.usageType:{
  dataClass: #MIXED,
  sizeCategory: #XL,
  serviceQuality: #D
}

@VDM.viewType: #COMPOSITE

@Metadata.allowExtensions: true

define view I_ChmlCmplncAnlyts2
  as select from I_ChmlCmplncInfo  as ChmlCmplncInfo
  -- inner join Composition
    inner join   I_ChmlComposition as _ChemicalComposition on  ChmlCmplncInfo.ChmlCmplncInfoUUID          =  _ChemicalComposition.ChmlCmplncInfoUUID
                                                           and _ChemicalComposition.ChmlCompositionType   <> 'MATLBSD1'
                                                           and _ChemicalComposition.ChmlCompositionType   <> 'MATLBSD2'
                                                           and _ChemicalComposition.ChmlCompositionStatus =  'RE'

{
      -- UUID of Unpackaged Product
  key cast( ChmlCmplncInfo.ChmlCmplncInfoUUID as ehfnd_cci_uuid preserving type )                    as ChmlCmplncInfoUUID,

      -- Composition Type
  key _ChemicalComposition.ChmlCompositionType,

      -- UUID of Company Substance from Composition of Unpackaged Product
  key _ChemicalComposition._ChmlComponent.SubstanceUUID,

      -- Material assigned to Unpackaged Product
  key cast( _MaterialAssignment.Material as ehfnd_cci_product preserving type )                      as Material,

      -- Indicator that Material assigned to unpackaged product is primary
  key _MaterialAssignment.MatlAssgmtIsPrimary,

      --Market Coverage Country
  key _MarketCoverage.Country,

      --Material Group
      cast(_MaterialAssignment._Product.ProductGroup as ehfnd_cci_material_group_l preserving type ) as MaterialGroup,

      --Production Status
      _MarketCoverage.ChmlCmplncProdnAllwd,

      -- Responsible Unit (used for DCL)
      ProdStewardshipRespUnit                                                                        as ProdStewardshipRespUnit,

      -- Indicator that Material is Sold (used for DCL)
      MaterialIsSold,

      -- Indicator that Material is Transported (used for DCL)
      MaterialIsTransported,

      -- Indicator that Material is Produced (used for DCL)
      MaterialIsProduced,

      -- Indicator that Material is Sourced (used for DCL)
      MaterialIsSourced,
      MaterialIsDisposed,
      MaterialIsEmissionRelevant
}
where
      ChmlCmplncInfoType = 'BU'
  and MaterialIsProduced = 'X'