I_ChgRecdRefOpSetTskListTP_2

@AbapCatalog.sqlViewName: 'ICHGRECREFROSTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Chg Record Ref Op Set Task List'
define view I_ChgRecdRefOpSetTskListTP_2
  as select from           I_ChgRecdRefOpSetTskListBsc as reference_ros
    left outer to one join I_BillOfOperations          as RefOpSetTskList on  reference_ros.ChgRecRefInternalKey1 = RefOpSetTskList.BillOfOperationsType
                                                                          and reference_ros.ChgRecRefInternalKey2 = RefOpSetTskList.BillOfOperationsGroup
                                                                          and reference_ros.ChgRecRefInternalKey3 = RefOpSetTskList.BillOfOperationsVariant
  association        to parent I_ChangeRecordTP_2   as _ChangeRecordAPITP        on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID
  association [1..1] to I_ChangeRecordDraftTP       as _ChangeRecordTP           on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefOpSetTskListBsc as _RefOpSetTskListExtension on $projection.ChangeRecordReferenceUUID = _RefOpSetTskListExtension.ChangeRecordReferenceUUID
{
  key   reference_ros.ChangeRecordReferenceUUID,
        case
           when RefOpSetTskList.BillOfOperationsType is null then cast(SUBSTRING( reference_ros.ChangeRecordReference, 1, 1) as plnty)
           else cast(RefOpSetTskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        case
        when RefOpSetTskList.BillOfOperationsGroup is null then  cast(SUBSTRING( reference_ros.ChangeRecordReference, 2, 9) as plnnr)
        else cast(RefOpSetTskList.BillOfOperationsGroup as plnnr)
        end                             as RefOpSetTskListGroup,

        case
         when RefOpSetTskList.BillOfOperationsVariant is null then cast (SUBSTRING( reference_ros.ChangeRecordReference, 10, 2) as plnal)
         else cast(RefOpSetTskList.BillOfOperationsVariant as plnal)
         end                            as RefOpSetTskList,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        //cast ('00000000' as plantext )  as BillOfOperationsDesc,


        reference_ros.ChangeRecordUUID,
        reference_ros.ChangeRecord,
        reference_ros.ChangeRecordReferenceType,
        reference_ros.ChangeRecordReferenceSubtype,
        reference_ros.ChangeRecordRefObjectUUID,
        reference_ros.ChangeRecordReference,
        reference_ros.ParentChangeRecordRefUUID,
        reference_ros.IsMainReference,
        reference_ros.CreatedByUser,
        reference_ros.CreationDateTime,
        reference_ros.LastChangedByUser,
        reference_ros.LastChangeDateTime,
        reference_ros.ChangeRecordItemRelevance,
        reference_ros.ChangeRecordVirtualRefInd,
        reference_ros.ChangeRecordItemProcgStatus,
        _ChangeRecordTP,
        _ChangeRecordAPITP
}
where
//  RefOpSetTskList.BillOfOperationsType = 'S'

reference_ros.ChangeRecordReferenceType = 'ROS'