I_ChgRecdRefFuncLocBOMTP

@AbapCatalog.sqlViewName: 'ICRREFFLBMTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Chg Recd Ref FL BOM Transactional - TP'
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
semanticKey: [ 'FunctionalLocation','Plant','BillOfMaterialVariantUsage','BillOfMaterialVariant'],
                writeDraftPersistence: 'PLMCRREFFLBOM_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }

@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #XXL}
define view I_ChgRecdRefFuncLocBOMTP
  as select from           I_ChgRecdRefFuncLocBOMBsc as reference_bom

    left outer to one join I_FunctionalLocBOMLink    as BOMLink on  reference_bom.ChgRecRefInternalKey1 = BOMLink.BillOfMaterialCategory
                                                                and reference_bom.ChgRecRefInternalKey2 = BOMLink.BillOfMaterial
                                                                and reference_bom.ChgRecRefInternalKey3 = BOMLink.BillOfMaterialVariant

  association [1..1] to I_ChangeRecordDraftTP as _ChangeRecordTP on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  //association [0..1] to E_ChgRecdRefEquipBOMBsc as _EQBOMExtension on $projection.ChangeRecordReferenceUUID = _EQBOMExtension.ChangeRecordReferenceUUID


{

  key        ChangeRecordReferenceUUID,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
               when BOMLink.FunctionalLocation is null then cast(SUBSTRING( reference_bom.ChangeRecordReference, 1, 30) as tplnr)
               else cast(BOMLink.FunctionalLocation as tplnr)
               end                                                      as FunctionalLocation,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
              when BOMLink.Plant is null then  cast(SUBSTRING( reference_bom.ChangeRecordReference, 31, 4) as werks_d)
              else cast(BOMLink.Plant as werks_d)
              end                                                       as Plant,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
              when BOMLink.BillOfMaterialVariantUsage is null then cast (SUBSTRING( reference_bom.ChangeRecordReference, 35, 1) as stlan)
              else cast(BOMLink.BillOfMaterialVariantUsage as stlan)
              end                                                       as BillOfMaterialVariantUsage,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             case
              when BOMLink.BillOfMaterialVariant is null then cast(SUBSTRING( reference_bom.ChangeRecordReference, 36, 2) as stalt)
              else cast(BOMLink.BillOfMaterialVariant as stalt)

              end                                                       as BillOfMaterialVariant,

             ChangeRecordUUID,

             ChangeRecordReferenceType,
             ChangeRecordReferenceSubtype,
             ChangeRecordReference,
             ParentChangeRecordRefUUID,
             IsMainReference,
             BillOfMaterialCategory,
             ChgRecdReasonForChange,
             ExpdCompltnDte,
             ChgRecdAuthznGrpText,
             ChgRecdNmbrChgSts,
             reference_bom.ChangeNumber,
             @Semantics.user.createdBy: true
             reference_bom.CreatedByUser,
             reference_bom.CreationDateTime,
             @Semantics.user.lastChangedBy: true
             reference_bom.LastChangedByUser,
             reference_bom.LastChangeDateTime,

             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             ChangeRecordItemRelevance,
             ChangeRecordVirtualRefInd,

             //For BOM Navigation

             cast( BOMLink.BillOfMaterial as cs_stlnr preserving type ) as BillOfMaterial,
             reference_bom.ChangeRecordRefObjectUUID,
             @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
             ChangeRecordItemProcgStatus,
             @ObjectModel.readOnly: true
             reference_bom.ChgRecdCurrentItemProcgStatus,
             @ObjectModel.readOnly: true
             ChgRecdItmTgtSts,
             @ObjectModel.readOnly: true
             ChgRecdItmDSgntr,
             @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
             _ChangeRecordTP

}
where
  ChangeRecordReferenceType = 'FBM'