I_ChgRecdRefCutPlngPrflTP_2

@AbapCatalog.sqlViewName: 'ICHGRECREFCPPTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Chg Record Cut Planning Profile'
define view I_ChgRecdRefCutPlngPrflTP_2
  as select from           I_ChgRecdRefCutPlngPrflBsc as reference_cpp
    left outer to one join I_BillOfOperations         as CutPlngPrflTskList on  reference_cpp.ChgRecRefInternalKey1 = CutPlngPrflTskList.BillOfOperationsType
                                                                            and reference_cpp.ChgRecRefInternalKey2 = CutPlngPrflTskList.BillOfOperationsGroup
                                                                            and reference_cpp.ChgRecRefInternalKey3 = CutPlngPrflTskList.BillOfOperationsVariant
  association        to parent I_ChangeRecordTP_2  as _ChangeRecordAPITP           on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID
  association [1..1] to I_ChangeRecordDraftTP      as _ChangeRecordTP              on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefCutPlngPrflBsc as _CutPlngPrflTskListExtension on $projection.ChangeRecordReferenceUUID = _CutPlngPrflTskListExtension.ChangeRecordReferenceUUID
{
  key   reference_cpp.ChangeRecordReferenceUUID,
        case
           when CutPlngPrflTskList.BillOfOperationsType is null then cast(SUBSTRING( reference_cpp.ChangeRecordReference, 1, 1) as plnty)
           else cast(CutPlngPrflTskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        case
        when CutPlngPrflTskList.BillOfOperationsGroup is null then  cast(SUBSTRING( reference_cpp.ChangeRecordReference, 2, 8) as plnnr)
        else cast(CutPlngPrflTskList.BillOfOperationsGroup as plnnr)
        end                             as CutPlngPrflTskListGroup,

        case
         when CutPlngPrflTskList.BillOfOperationsVariant is null then cast (SUBSTRING( reference_cpp.ChangeRecordReference, 10, 2) as plnal)
         else cast(CutPlngPrflTskList.BillOfOperationsVariant as plnal)
         end                            as CutPlngPrflTskList,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        //cast ('00000000' as plantext )  as BillOfOperationsDesc,


        reference_cpp.ChangeRecordUUID,
        reference_cpp.ChangeRecord,
        reference_cpp.ChangeRecordReferenceType,
        reference_cpp.ChangeRecordReferenceSubtype,
        reference_cpp.ChangeRecordRefObjectUUID,
        reference_cpp.ChangeRecordReference,
        reference_cpp.ParentChangeRecordRefUUID,
        reference_cpp.IsMainReference,
        reference_cpp.CreatedByUser,
        reference_cpp.CreationDateTime,
        reference_cpp.LastChangedByUser,
        reference_cpp.LastChangeDateTime,
        reference_cpp.ChangeRecordItemRelevance,
        reference_cpp.ChangeRecordVirtualRefInd,
        reference_cpp.ChangeRecordItemProcgStatus,
        _ChangeRecordTP,
        _ChangeRecordAPITP
}
where
  reference_cpp.ChangeRecordReferenceType = 'CPP'