I_ChgRecdFuncLocBillOfMatTP_2

@AbapCatalog.sqlViewName: 'ICHGRECDFBMTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Chg Record Functional Location BOM'
define view I_ChgRecdFuncLocBillOfMatTP_2
  as select from           I_ChgRecdRefFuncLocBOMBsc as reference_bom

    left outer to one join I_FunctionalLocBOMLink    as BOMLink on  reference_bom.ChgRecRefInternalKey1 = BOMLink.BillOfMaterialCategory
                                                                and reference_bom.ChgRecRefInternalKey2 = BOMLink.BillOfMaterial
                                                                and reference_bom.ChgRecRefInternalKey3 = BOMLink.BillOfMaterialVariant
  association        to parent I_ChangeRecordTP_2 as _ChangeRecordAPITP on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID
  association [1..1] to I_ChangeRecordDraftTP     as _ChangeRecordTP    on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  //association [0..1] to E_ChgRecdRefEquipBOMBsc   as _BOMExtension      on $projection.ChangeRecordReferenceUUID = _BOMExtension.ChangeRecordReferenceUUID


{

  key        reference_bom.ChangeRecordReferenceUUID,
             case
              when BOMLink.FunctionalLocation is null then cast(SUBSTRING( reference_bom.ChangeRecordReference, 1, 30) as tplnr)
              else cast(BOMLink.FunctionalLocation as tplnr)
              end                                                       as FunctionalLocation,

             case
              when BOMLink.Plant is null then  cast(SUBSTRING( reference_bom.ChangeRecordReference, 31, 4) as werks_d)
              else cast(BOMLink.Plant as werks_d)
              end                                                       as Plant,

             case
              when BOMLink.BillOfMaterialVariantUsage is null then cast (SUBSTRING( reference_bom.ChangeRecordReference, 35, 1) as stlan)
              else cast(BOMLink.BillOfMaterialVariantUsage as stlan)
              end                                                       as BillOfMaterialVariantUsage,

             case
              when BOMLink.BillOfMaterialVariant is null then cast(SUBSTRING( reference_bom.ChangeRecordReference, 36, 2) as stalt)
              else cast(BOMLink.BillOfMaterialVariant as stalt)

              end                                                       as BillOfMaterialVariant,
             reference_bom.ChangeRecordUUID,
             reference_bom.ChangeRecord,
             reference_bom.ChangeRecordReferenceType,
             reference_bom.ChangeRecordReferenceSubtype,
             reference_bom.ChangeRecordReference,
             reference_bom.ParentChangeRecordRefUUID,
             reference_bom.IsMainReference,
             BOMLink.BillOfMaterialCategory,
             reference_bom.ChangeNumber,
             reference_bom.CreatedByUser,
             reference_bom.CreationDateTime,
             reference_bom.LastChangedByUser,
             reference_bom.LastChangeDateTime,
             reference_bom.ChangeRecordItemRelevance,
             reference_bom.ChangeRecordVirtualRefInd,

             cast( BOMLink.BillOfMaterial as cs_stlnr preserving type ) as BillOfMaterial,
             reference_bom.ChangeRecordRefObjectUUID,
             reference_bom.ChangeRecordItemProcgStatus,
             _ChangeRecordTP,
             _ChangeRecordAPITP
}
where
  reference_bom.ChangeRecordReferenceType = 'FBM'