I_CashDiscountDueStatusText

@AbapCatalog.sqlViewName: 'ICDDUESTSTXT'
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@VDM.viewType: #BASIC
//@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API

@AccessControl.authorizationCheck: #NOT_REQUIRED 
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'CashDiscount1DueStatus'
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.serviceQuality: #A 
@ObjectModel.usageType.dataClass: #META
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
@EndUserText.label: 'Cash Discount Due Status descriptions'
@ClientHandling.algorithm: #SESSION_VARIABLE 
@Search.searchable: true
@Metadata.ignorePropagatedAnnotations: true

define view I_CashDiscountDueStatusText 
as select from dd07t

association[1..1] to I_CashDiscountDueStatus as _CashDiscount1DueStatus on $projection.CashDiscount1DueStatus = _CashDiscount1DueStatus.CashDiscount1DueStatus
association[0..1] to I_Language as _Language on $projection.Language = _Language.Language

{
    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key cast( dd07t.ddlanguage as spras preserving type ) as Language,
    @Search.defaultSearchElement: false
    @ObjectModel.foreignKey.association: '_CashDiscount1DueStatus'
    @ObjectModel.text.element: ['CashDiscount1DueStatusName']
    key cast( domvalue_l as far_sym_due ) as CashDiscount1DueStatus,
    @Analytics.hidden: true
    @Consumption.hidden: true
    dd07t.domvalue_l as DomainValue,       
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8
    @Search.ranking: #HIGH
    @Semantics.text: true
    @UI.hidden: true
    dd07t.ddtext as CashDiscount1DueStatusName,
    @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, 
                                      #TO_COMPOSITION_ROOT]      
    //Associations

    _CashDiscount1DueStatus,
    _Language
}
where 
      domname = 'FAR_SYM_DUE' and (dd07t.as4local = 'A');