I_CapacityRequirementItemCapC

DDL: I_CAPACITYREQUIREMENTITEMCAPC SQL: IPPCAPRQMITMCAPC Type: view COMPOSITE

Capacity Requirement Item Capacity - Cube

I_CapacityRequirementItemCapC is a Composite CDS View (Cube) that provides data about "Capacity Requirement Item Capacity - Cube" in SAP S/4HANA. It reads from 1 data source (I_CapacityRequirementItemCap) and exposes 67 fields with key fields CapacityRequirement, CapacityRequirementItem, CapacityCategoryAllocation.

1 data source(s) 67 fields

Data Sources (1)

SourceAliasJoin Type
I_CapacityRequirementItemCap I_CapacityRequirementItemCap from

Annotations (12)

NameValueLevelField
AbapCatalog.sqlViewName IPPCAPRQMITMCAPC view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #MANDATORY view
Analytics.dataCategory #CUBE view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.allowExtensions true view
ObjectModel.modelingPattern #ANALYTICAL_CUBE view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #COMPOSITE view
EndUserText.label Capacity Requirement Item Capacity - Cube view

Fields (67)

KeyFieldSource TableSource FieldDescription
KEY CapacityRequirement CapacityRequirement
KEY CapacityRequirementItem CapacityRequirementItem
KEY CapacityCategoryAllocation CapacityRqmtItemCapacity
CapacityReqConfirmation CapacityRqmtConfirmation
WorkCenterInternalID WorkCenterInternalID
WorkCenterTypeCode WorkCenterTypeCode_2
CapacityInternalID CapacityInternalID
PlannedOrder PlannedOrder
OrderInternalID OrderInternalID
OrderID OrderID
OrderOperationInternalID OrderOperationInternalID
Operation Operation
Operation_2 Operation_2
SalesOperationsPlanningOrder SalesOperationsPlanningOrder
PersonnelNumber PersonnelNumber
CapacityRequirementDistrKey CapacityRequirementDistrKey
CapacityRequirementUnit CapacityRequirementUnit
ScheduledCapReqOpSegSetupDurn ScheduledCapReqOpSegSetupDurn
RemainingCapReqOpSegSetupDurn RemainingCapReqOpSegSetupDurn
ScheduledCapReqOpSegProcgDurn ScheduledCapReqOpSegProcgDurn
RemainingCapReqOpSegProcgDurn RemainingCapReqOpSegProcgDurn
ScheduledCapReqOpSegTrdwnDurn ScheduledCapReqOpSegTrdwnDurn
RemainingCapReqOpSegTrdwnDurn RemainingCapReqOpSegTrdwnDurn
OperationEarliestStartDate OperationEarliestStartDate
OperationEarliestStartTime OperationEarliestStartTime
OperationEarliestEndDate OperationEarliestEndDate
OperationEarliestEndTime OperationEarliestEndTime
OperationLatestStartDate OperationLatestStartDate
OperationLatestStartTime OperationLatestStartTime
OperationLatestEndDate OperationLatestEndDate
OperationLatestEndTime OperationLatestEndTime
ActualStartDate ActualStartDate
ActualStartTime ActualStartTime
ActualEndDate ActualEndDate
ActualEndTime ActualEndTime
ErlstSchedldProcStrtDte ErlstSchedldProcStrtDte
ErlstSchedldProcStrtTime ErlstSchedldProcStrtTime
ErlstSchedldTrdwnStrtDte ErlstSchedldTrdwnStrtDte
ErlstSchedldTrdwnStrtTime ErlstSchedldTrdwnStrtTime
LtstSchedldProcStrtDte LtstSchedldProcStrtDte
LtstSchedldProcStrtTime LtstSchedldProcStrtTime
LtstSchedldTrdwnStrtDte LtstSchedldTrdwnStrtDte
LtstSchedldTrdwnStrtTime LtstSchedldTrdwnStrtTime
ActualNumberOfSplits ActualNumberOfSplits
CapacityRequirementSplit CapacityRequirementSplit
ObjectInternalID ObjectInternalID
OrderObjectInternalID OrderObjectInternalID
StandardWorkQuantityUnit StandardWorkQuantityUnit
PlannedWorkQuantity PlannedWorkQuantity
ActualWorkQuantity ActualWorkQuantity
_CapacityRequirement _CapacityRequirement
_CapacityRequirementItem _CapacityRequirementItem
_CapacityRequirementConf _CapacityRequirementConf
_Capacity _Capacity
_PlannedOrder _PlannedOrder
_Order _Order
_OrderItem _OrderItem
_OrderOperation _OrderOperation
_OrderInternalID _OrderInternalID
_SalesOperationsPlanningOrder _SalesOperationsPlanningOrder
_Employee _Employee
_Employment _Employment
_WorkCenter _WorkCenter_2
_WorkCenterType _WorkCenterType_2
_StatusObjectStatus _StatusObjectStatus
_OrderStatusObjectStatus _OrderStatusObjectStatus
_UnitOfMeasure _UnitOfMeasure 
@AbapCatalog.sqlViewName: 'IPPCAPRQMITMCAPC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_StatusObjectStatus', '_OrderStatusObjectStatus']
@Analytics.dataCategory: #CUBE
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@ObjectModel.modelingPattern: #ANALYTICAL_CUBE
@ObjectModel.supportedCapabilities: [#ANALYTICAL_PROVIDER]
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Capacity Requirement Item Capacity - Cube'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_CapacityRequirementItemCapC
  as select from I_CapacityRequirementItemCap
{
      // Key

      @ObjectModel.foreignKey.association: '_CapacityRequirement'
  key CapacityRequirement,
      @ObjectModel.foreignKey.association: '_CapacityRequirementItem'
  key CapacityRequirementItem,
  key CapacityRqmtItemCapacity as CapacityCategoryAllocation,  // keep old name for compat. reasons


      // Assignments

      @ObjectModel.foreignKey.association: '_CapacityRequirementConf'
      CapacityRqmtConfirmation as CapacityReqConfirmation,     // keep old name for compat. reasons

      @ObjectModel.foreignKey.association: '_WorkCenter'
      WorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_WorkCenterType'
      WorkCenterTypeCode_2 as WorkCenterTypeCode,
      @ObjectModel.foreignKey.association: '_Capacity'
      CapacityInternalID,
      @ObjectModel.foreignKey.association: '_PlannedOrder'
      PlannedOrder,
      @ObjectModel.foreignKey.association: '_OrderInternalID'      
      OrderInternalID,
      @ObjectModel.foreignKey.association: '_Order'
      OrderID,
      @ObjectModel.foreignKey.association: '_OrderOperation'
      OrderOperationInternalID,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'Operation_2'
      Operation,   // with conversion exit NUMCV

      Operation_2, // without conversion exit

      @ObjectModel.foreignKey.association: '_SalesOperationsPlanningOrder'
      SalesOperationsPlanningOrder,
      @ObjectModel.foreignKey.association: '_Employment' 
      PersonnelNumber,
      CapacityRequirementDistrKey,

      // Capacity Durations

      @Semantics.unitOfMeasure: true
      CapacityRequirementUnit,
      @Semantics.calendarItem.duration: true
      ScheduledCapReqOpSegSetupDurn,
      @Semantics.calendarItem.duration: true
      RemainingCapReqOpSegSetupDurn,
      @Semantics.calendarItem.duration: true
      ScheduledCapReqOpSegProcgDurn,
      @Semantics.calendarItem.duration: true
      RemainingCapReqOpSegProcgDurn,
      @Semantics.calendarItem.duration: true
      ScheduledCapReqOpSegTrdwnDurn,
      @Semantics.calendarItem.duration: true
      RemainingCapReqOpSegTrdwnDurn,

      // Dates and Times

      @Semantics.calendarItem.dtStart: true
      OperationEarliestStartDate,
      OperationEarliestStartTime,
      @Semantics.calendarItem.dtEnd: true
      OperationEarliestEndDate,
      OperationEarliestEndTime,
      @Semantics.calendarItem.dtStart: true
      OperationLatestStartDate,
      OperationLatestStartTime,
      @Semantics.calendarItem.dtEnd: true
      OperationLatestEndDate,
      OperationLatestEndTime,
      @Semantics.calendarItem.dtStart: true
      ActualStartDate,
      ActualStartTime,
      @Semantics.calendarItem.dtEnd: true
      ActualEndDate,
      ActualEndTime,
      @Semantics.calendarItem.dtEnd: true
      ActualForecastEndDate,
      ActualForecastEndTime,

      @Semantics.calendarItem.dtStart: true
      ErlstSchedldProcStrtDte,
      ErlstSchedldProcStrtTime,
      @Semantics.calendarItem.dtStart: true
      ErlstSchedldTrdwnStrtDte,
      ErlstSchedldTrdwnStrtTime,
      @Semantics.calendarItem.dtStart: true
      LtstSchedldProcStrtDte,
      LtstSchedldProcStrtTime,
      @Semantics.calendarItem.dtStart: true
      LtstSchedldTrdwnStrtDte,
      LtstSchedldTrdwnStrtTime,

      // Split data

      ActualNumberOfSplits,
      CapacityRequirementSplit,
      ObjectInternalID,
      OrderObjectInternalID,
      case _StatusObjectStatus.StatusIsActive 
        when 'X' then 'X'
        else '' 
      end as CapacitySplitIsDispatched,

      // Work Quantity PM & PS

      @Semantics.unitOfMeasure: true
      StandardWorkQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit'
      @Aggregation.default: #SUM
      PlannedWorkQuantity,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit'
      @Aggregation.default: #SUM
      ActualWorkQuantity,
      @Semantics.quantity.unitOfMeasure: 'StandardWorkQuantityUnit'
      @Aggregation.default: #SUM
      ForecastedWorkQty,

      // Associations

      _CapacityRequirement,
      _CapacityRequirementItem,
      _CapacityRequirementConf,
      _Capacity,
      _PlannedOrder,
      _Order,
      _OrderItem,
      _OrderOperation,
      _OrderInternalID,
      _SalesOperationsPlanningOrder,
      _Employee,
      _Employment,
      _WorkCenter_2     as _WorkCenter,
      _WorkCenterType_2 as _WorkCenterType,
      _StatusObjectStatus,
      _OrderStatusObjectStatus,
      _UnitOfMeasure
};

Learn More