I_CADocumentBPItemUI

@AbapCatalog.viewEnhancementCategory: [#NONE]
@EndUserText.label: 'Business Partner Item'
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C

@VDM.viewType: #COMPOSITE
define view entity I_CADocumentBPItemUI
  as select from R_CADocumentBPItemTP
  association [0..1] to I_CAProviderContractItem as _ProviderContractItem on  _ProviderContractItem.CAProviderContract           = $projection.CAContract
                                                                          and _ProviderContractItem.CAProviderContractItemNumber = $projection.CAProviderContractItemNumber

{
  key CADocumentNumber,
  key CARepetitionItemNumber,
  key CABPItemNumber,
  key CASubItemNumber,
      BusinessPartner,
      CAContract,
      CAProviderContractItemNumber,
      _ProviderContractItem.CAProviderContractItemUUID,
      cast(bintohex(_ProviderContractItem.CAProviderContractItemUUID) as vtpid_c_kk) as CAProviderContractItemCharUUID,

      case
        when CAAmountInTransactionCurrency >= 0 then cast('X' as bpitem_is_receivable_kk)
        else cast('' as bpitem_is_receivable_kk)
        end                                                      as CADocumentBPItemIsReceivable,

      //for Authorization Check

      CompanyCode,
      CADocumentOriginCode,
      BusinessArea,
      Segment,
      ContractAccount,
      CASubApplication,
      _CAPartner,
      _ProviderContract,
      _BusinessPartner
}