I_BusinessObjectEventTask

@AbapCatalog.sqlViewName: 'IBUSOBJEVTTSK'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'SAP Obj Type and SAP Obj Tsk Type Mappg'
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C

define view I_BusinessObjectEventTask
  as select from I_SAPObjectType
    inner join   I_SAPObjectRepresentation on  I_SAPObjectRepresentation.SAPObjectType               = I_SAPObjectType.SAPObjectType
                                           and I_SAPObjectRepresentation.SAPObjectRepresentationType = 'SOA'
    inner join   I_SAPObjectTypeEventCode  on I_SAPObjectTypeEventCode.SAPObjectType = I_SAPObjectType.SAPObjectType
    inner join   I_SAPObjectTaskType       on I_SAPObjectTypeEventCode.SAPObjectTaskType = I_SAPObjectTaskType.SAPObjectTaskType
  association [1..1] to I_SAPObjectTypeEvtCodeTxt as _TaskText on  $projection.SAPObjectType     = _TaskText.SAPObjectType
                                                               and $projection.SAPObjectTaskType = _TaskText.SAPObjectTaskType
                                                               and _TaskText.Language            = $session.system_language
  association [1..1] to I_SAPObjectTypeText       as _TypeText on  $projection.SAPObjectType = _TypeText.SAPObjectType
                                                               and _TypeText.Language        = $session.system_language
{
  key   I_SAPObjectTypeEventCode.SAPObjectType,
  key   I_SAPObjectTaskType.SAPObjectTaskCode,
  key   I_SAPObjectRepresentation.SAPObjectRepresentation,
  key   I_SAPObjectTypeEventCode.SAPObjectTaskType,
  key   I_SAPObjectTypeEventCode.SAPObjectEventCode,
  key   I_SAPObjectRepresentation.SAPObjectRepresentationType,
  key   _TypeText[1:inner].SAPObjectTypeName,
  key   _TaskText[1:inner].SAPObjectTaskTypeName,
        /* Associations */
        _TypeText
        //        _TaskText

}
union select from I_SAPObjectType
  inner join      I_SAPObjectRepresentation    on  I_SAPObjectRepresentation.SAPObjectType               = I_SAPObjectType.SAPObjectType
                                               and I_SAPObjectRepresentation.SAPObjectRepresentationType = 'SOA'
  inner join      I_BusinessEventBindingHeader on I_BusinessEventBindingHeader.SAPObjectType = I_SAPObjectType.SAPObjectType
  inner join      I_SAPObjectTaskType          on I_SAPObjectTaskType.SAPObjectTaskCode = I_BusinessEventBindingHeader.EventOperation

association [1..1] to I_SAPObjectTypeText as _TypeText on  $projection.SAPObjectType = _TypeText.SAPObjectType
                                                       and _TypeText.Language        = $session.system_language
{

  key   I_BusinessEventBindingHeader.SAPObjectType,
  key   I_SAPObjectTaskType.SAPObjectTaskCode,
  key   I_SAPObjectRepresentation.SAPObjectRepresentation,
  key   I_SAPObjectTaskType.SAPObjectTaskType,
  key   cast( upper (I_SAPObjectTaskType.SAPObjectTaskCode) as abap.char( 32 ))                     as SAPObjectEventCode,
  key   I_SAPObjectRepresentation.SAPObjectRepresentationType,
  key   _TypeText[1:inner].SAPObjectTypeName,
  key   concat_with_space( _TypeText[1:inner].SAPObjectTypeName, I_SAPObjectTaskType.EventTypeDescription, 1 ) as SAPObjectTaskTypeName,
        /* Associations */
        _TypeText
        //        _TaskText

}