I_BusTransacTypeHierNode

@EndUserText.label: 'Business Transaction Type Hier Node'
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFIBUSTRANTYPEN'
@Hierarchy.parentChild:
[{ recurse:          {   parent: ['ParentNode'],   child:  ['HierarchyNode']  },
  siblingsOrder:    [{   by: 'HierarchyNodeSequence',    direction: 'ASC'   }],
  directory:        '_Hierarchy'
  }]
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'HierarchyNode'
@ObjectModel.modelingPattern: #ANALYTICAL_PARENT_CHILD_HIERARCHY_NODE
@ObjectModel.supportedCapabilities: #ANALYTICAL_PARENT_CHILD_HIERARCHY_NODE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@Analytics.internalName: #LOCAL

@ObjectModel: {usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL},
  dataCategory: #HIERARCHY
}

define view I_BusTransacTypeHierNode
  as select from hrrp_node_n

  association [0..*] to I_BusTransacTypeHierNodeTxt as _Text                    on  $projection.BusTransacTypeHier      = _Text.BusTransacTypeHier
                                                                                and $projection.HierarchyNode           = _Text.HierarchyNode
                                                                                and $projection.BusinessTransactionType = '' // just to show that this association is only to be followed if FunctionalArea is blank


  association [0..1] to I_BusinessTransactionType   as _BusinessTransactionType on  $projection.BusinessTransactionType = _BusinessTransactionType.BusinessTransactionType

  association [1..1] to I_BusTransacTypeHier        as _Hierarchy               on  $projection.BusTransacTypeHier = _Hierarchy.BusTransacTypeHier
                                                                                and $projection.ValidityEndDate    = _Hierarchy.ValidityEndDate


{
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key hrrp_node_n.hryid_42                                as BusTransacTypeHier,
      @ObjectModel.text.association: '_Text'
  key hrrp_node_n.hrynode                              as HierarchyNode,
      @Semantics.businessDate.to: true
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
  key cast(hrrp_node_n.hryvalto as fis_datbi preserving type )  as ValidityEndDate,
      @Semantics.businessDate.from: true
      cast(hrrp_node_n.hryvalfrom as fis_datab preserving type ) as ValidityStartDate,
      hrrp_node_n.parnode                              as ParentNode,
      @VDM.lifecycle.status:    #DEPRECATED
      cast( '000000000000001' as hryversn )                           as HierarchyVersion,
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BusTransTypeStdVH',
                     element: 'BusinessTransactionType' }
        }]
      @ObjectModel.foreignKey.association: '_BusinessTransactionType'
      cast ( hrrp_node_n.cbttype as fins_bttype preserving type )    as BusinessTransactionType,
      hrrp_node_n.hryseqnbr                            as HierarchyNodeSequence,
      hrrp_node_n.hrylevel                             as HierarchyNodeLevel,
      hrrp_node_n.nodetype                             as NodeType,
      hrrp_node_n.nodevalue                            as HierarchyNodeVal,


      _Text,
      _BusinessTransactionType,
      _Hierarchy

}
where
      hrrp_node_n.nodetype          <> 'D'
  and hrrp_node_n.hrytyp =  'GL03';