I_BusPartAddressUsageProcTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Business Partner Addr Usage (Proc Data)'

@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
define view entity I_BusPartAddressUsageProcTP
  as select from I_BusPartAddressUsageProc
  association [1..1] to I_BusinessPartnerProcessTP            as _BusinessPartner        on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association        to parent I_BusinessPartnerAddressProcTP as _BusinessPartnerAddress on  $projection.MasterDataChangeProcess = _BusinessPartnerAddress.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _BusinessPartnerAddress.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _BusinessPartnerAddress.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _BusinessPartnerAddress.MDChgProcessSrceObject
                                                                                         and $projection.AddressNumber           = _BusinessPartnerAddress.AddressNumber
  association [0..1] to I_BusinessPartnerAddressType          as _AddressType            on  $projection.AddressUsage = _AddressType.AddressType
  association [0..1] to I_BPProcessKPIRecordType              as _RecordType             on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH             as _KPIUpdateStatusText    on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages             as _RecordMessages         on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
{
      //I_BusPartAddressUsageProc

  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key ValidityEndDate,
  key AddressUsage,
      @Search.defaultSearchElement: true
  key AddressNumber,
      BusinessPartner,
      ValidityStartDate,
      @Semantics.businessDate.from: true
      case when ValidityStartDate != 00010101000000
      then tstmp_to_dats(ValidityStartDate,'UTC',  $session.client, 'NULL')
      else cast ( '00010103' as abap.dats )
      end                                                            as AddressUsageValidityStartDate,
      @Semantics.businessDate.to: true
      case when ValidityEndDate != 00010101000000
      then tstmp_to_dats(ValidityEndDate,'UTC',  $session.client, 'NULL')
      else cast ( '99991231' as abap.dats)
      end                                                            as AddressUsageValidityEndDate,
      @Semantics.booleanIndicator: true
      case AddressUsage
      when 'XXDEFAULT' then 'X'
      else StandardUsage end                                         as StandardUsage,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      MDChgProcSrceLastChgdDateTime,
      /* Record Identification */
      /* Has been moved to a virtual field in the projection layer, therefore the dummy entry */
      cast( '' as abap.char(209) )  as AddressLine1Text,
      cast( case
        when MDChgProcessSourceModified = '' then 'N'
        when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified ) as MDChgProcKPIUpdateStatus,

      _BusinessPartner,
      _BusinessPartnerAddress,
      _BPProtectedAddress,
      _AddressType,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages
}