I_BomHeaderChanges

@AbapCatalog.sqlViewName: 'IBOMHDRCHANGES'
@ClientHandling.type : #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@EndUserText.label: 'BOM Header Changes'
define view I_BomHeaderChanges
  as select distinct from stko              as HeaderChanges
    inner join   I_ChangeMaster    as aenr on HeaderChanges.aennr = aenr.ChangeNumber
    inner join   I_MaterialBOMLink as mast on  HeaderChanges.stlnr = mast.BillOfMaterial
                                           and HeaderChanges.stlal = mast.BillOfMaterialVariant
                                           and HeaderChanges.stlty = 'M'
{
  key HeaderChanges.stlnr     as BillOfMaterial,
  key HeaderChanges.stlty     as BillOfMaterialCategory,
  key HeaderChanges.stlal     as BillOfMaterialVariant,
  key HeaderChanges.aennr     as EngineeringChangeDocument,
  key HeaderChanges.bom_versn as BillOfMaterialVersion,
  key mast.Material,
  key mast.Plant,
  key mast.BillOfMaterialVariantUsage,
      aenr.ChangeNumberStatus,
      aenr.ChangeNumberValidFromDate,
      aenr.ChangeNumberCreatedByUser,
      aenr.ChangeNumberCreationDate
}

// Added to get data from Sales Order BOM as well 

union all select distinct from stko              as HeaderChanges
    inner join   I_ChangeMaster    as aenr on HeaderChanges.aennr = aenr.ChangeNumber
    inner join   I_SalesOrderBOMLink as kdst on  HeaderChanges.stlnr = kdst.BillOfMaterial
                                             and HeaderChanges.stlal = kdst.BillOfMaterialVariant
                                             and HeaderChanges.stlty = 'K'
{
  key HeaderChanges.stlnr     as BillOfMaterial,
  key HeaderChanges.stlty     as BillOfMaterialCategory,
  key HeaderChanges.stlal     as BillOfMaterialVariant,
  key HeaderChanges.aennr     as EngineeringChangeDocument,
  key HeaderChanges.bom_versn as BillOfMaterialVersion,
  key kdst.Material,
  key kdst.Plant,
  key kdst.BillOfMaterialVariantUsage,
      aenr.ChangeNumberStatus,
      aenr.ChangeNumberValidFromDate,
      aenr.ChangeNumberCreatedByUser,
      aenr.ChangeNumberCreationDate
}

union all select distinct from stko_draft_v2   as HeaderDraftChanges
  inner join          I_ChangeMaster as aenr on HeaderDraftChanges.engineeringchangedocforedit = aenr.ChangeNumber
{
  key HeaderDraftChanges.billofmaterial             as BillOfMaterial,
  key HeaderDraftChanges.billofmaterialcategory     as BillOfMaterialCategory,
  key HeaderDraftChanges.billofmaterialvariantforedit      as BillOfMaterialVariant,
  key HeaderDraftChanges.engineeringchangedocforedit  as EngineeringChangeDocument,
  key HeaderDraftChanges.billofmaterialversionforedit      as BillOfMaterialVersion,
  key HeaderDraftChanges.materialforedit as Material,
  key HeaderDraftChanges.plantforedit as Plant,
  key HeaderDraftChanges.billofmaterialvariantusage as BillOfMaterialVariantUsage,
      aenr.ChangeNumberStatus,
      aenr.ChangeNumberValidFromDate,
      aenr.ChangeNumberCreatedByUser,
      aenr.ChangeNumberCreationDate
}