I_BillingDocItemPartnerBasic

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Billing Document Item Partner Basic'
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED,
  privilegedAssociations: [ '_Address', '_DfltAddrRprstn' ]
}
@AbapCatalog: {
  sqlViewName: 'ISDBILDOCITPTBC',
  compiler.compareFilter: true,
  preserveKey: true
}
@ObjectModel: {
   representativeKey: 'PartnerFunction',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
}
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations: true

define view I_BillingDocItemPartnerBasic
  as select from I_SDDocumentItemPartner    as Partner
    inner join   I_BillingDocumentItemBasic as BillingDocumentItem on  BillingDocumentItem.BillingDocument               = Partner.SDDocument
                                                                   and BillingDocumentItem.BillingDocumentItemInPartSgmt = Partner.SDDocumentItem

  association [1..1] to I_BillingDocumentBasic     as _BillingDocumentBasic on  $projection.BillingDocument = _BillingDocumentBasic.BillingDocument
  association [1..1] to I_BillingDocumentItemBasic as _ItemBasic            on  $projection.BillingDocument     = _ItemBasic.BillingDocument
                                                                            and $projection.BillingDocumentItem = _ItemBasic.BillingDocumentItem

{

      //--[ GENERATED:012:GlBfhyJl7kY4v5RWfCiSf0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BillingDocumentBasicStdVH',
                     element: 'BillingDocument' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_BillingDocumentBasic'
  key cast(Partner.SDDocument as vbeln_vf preserving type ) as BillingDocument,

      //--[ GENERATED:012:GlBfhyJl7kY4v5RWfCiSf0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_BillgDocItmBscStdVH',
                     element: 'BillingDocumentItem' },
          additionalBinding: [{ localElement: 'BillingDocument',
                                element: 'BillingDocument' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_ItemBasic'
  key BillingDocumentItem.BillingDocumentItem,
      @ObjectModel.foreignKey.association: '_PartnerFunction'
  key Partner.PartnerFunction,

      Partner.Customer,

      Partner.Supplier,

      Partner.Personnel,
      @ObjectModel.foreignKey.association: '_Address'
      Partner.AddressID,
      Partner.ContactPerson,

      Partner.AddressPersonID,
      Partner.ReferenceBusinessPartner,
      Partner.BPRefAddressIDForDocSpcfcAddr,
      Partner.SDDocPartnerAddressRefType,

      Partner.AddressObjectType,
      Partner.VATRegistration,
      Partner.UnloadingPointName,

      //Association

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _BillingDocumentBasic,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _ItemBasic,
      Partner._PartnerFunction,
      Partner._Address,
      Partner._BusinessPartnerAddress,
      Partner._BPRefAddressForDocSpcfcAddr,
      Partner._DfltAddrRprstn
}