I_BankAccountBasicData

@AbapCatalog.sqlViewName: 'IBANKACNTBASIC'
@VDM.viewType: #BASIC
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName:#LOCAL
@AbapCatalog.preserveKey:true
@ObjectModel.usageType: {
dataClass: #MASTER,
sizeCategory: #M,
serviceQuality: #C }
@ObjectModel: { supportedCapabilities:
  [ #ANALYTICAL_DIMENSION,
    #CDS_MODELING_ASSOCIATION_TARGET,
    #SQL_DATA_SOURCE,
    #CDS_MODELING_DATA_SOURCE,
    #SEARCHABLE_ENTITY ],
 modelingPattern: #ANALYTICAL_DIMENSION,
 representativeKey: 'BankAccountInternalID' }
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Basic Data of Bank Account Master Data'
@Search.searchable: true
@Metadata.allowExtensions:true

define view I_BankAccountBasicData
  as select from fclm_bam_amd
  association [0..1] to I_BankAcctContrTypeVH as _ContractType on $projection.BankAccountType = _ContractType.BankAccountType
  association [0..*] to I_BankAccountType          as _BankAccountType          on  $projection.BankAccountType = _BankAccountType.BankAccountType
  association [0..1] to I_Country                  as _BankCountry              on  $projection.BankCountry = _BankCountry.Country
  association [0..1] to I_CompanyCode         as _CompanyCode     on $projection.CompanyCode = _CompanyCode.CompanyCode
{
  key acc_id                     as BankAccountInternalID,
      banks                      as BankCountry,
      bankl                      as Bank,
      acc_num                    as BankAccountNumber,
      acc_type_id                as BankAccountType,
      _ContractType.BankAccountContractType,
      valid_from                 as ValidityStartDate,
      valid_to                   as ValidityEndDate,
      iban                       as IBAN,
      status                     as BankAccountStatus,
      bukrs                      as CompanyCode,
      prctr                      as ProfitCenter,
      gsber                      as BusinessArea,
      segment                    as Segment,
      beneficial                 as BankAccountHolderName,
      bank_contact               as BankContactPerson,
      rel_manager                as BankRelationshipManager,
      company_contact            as CompanyContactPerson,
      account_supervisor         as BankAccountSupervisor,
      created_by                 as CreatedByUser,
      opened_by                  as OpenedByUser,
      changed_by                 as LastChangedByUser,
      reviewed_by                as ReviewedByUser,
      closed_by                  as ClosedByUser,
      deleted_flag               as IsMarkedForDeletion,
      cutoff_time_d              as DomesticCutOffTime,
      cutoff_time_c              as CrossBorderCutOffTime,
      planned_closing_date       as PlannedClosingDate,
      created_at_dat             as CreationDate,
      created_at_tim             as CreationTime,
      opened_at_dat              as OpenedDate,
      opened_at_tim              as OpenedTime,
      changed_at_dat             as LastChangeDate,
      changed_at_tim             as LastChangeTime,
      closed_at_dat              as ClosedDate,
      closed_at_tim              as ClosedTime,
      control_key                as BankControlKey,
      iban_valid_from            as IBANValidityStartDate,
      // vgtyp                      as TransactionCode,

      vgtyp                      as PaymentTransactionTypeGroup,
      waers                      as BankAccountCurrency,
      cash_pool_id               as LeadingCashPoolID,
      cash_pool_id_participant   as ParticipantCashPoolID,
      @Semantics.amount.currencyCode: 'BankAccountCurrency'
      cash_pool_target_amt_max   as MaxTargetAmount,
      @Semantics.amount.currencyCode: 'BankAccountCurrency'
      cash_pool_transfer_amt_min as MinTransferAmount,
      payment_method_l           as LeadingPaymentMethod,
      payment_method_p           as ParticipantPaymentMethod,
      payment_service_provider   as PaymentServiceProvider,
      tolerance_group            as CashToleranceGroup,
      reconcile_intraday         as IntradayIsReconciled,
      objnr                      as TreasuryFinancialObject,
      bs_upload_time             as BankStatementCheckTime,
      edbsum                     as BankStatementImportMethod,
      idbsum                     as IntraDayBankStateImportMethod,
      importing_channel          as BankStatementImportChannel,
      upload_bs_flag             as IsUploadOfIntraDayStatement,
      reconcile_endofday         as EndOfDayIsReconciled,
      ihb_servicer               as IHBAccountHolder,
      _ContractType,
      _BankCountry,
      _BankAccountType,
      _CompanyCode
}
where
      revision     =  '0000'
  and(
       status       =  '02' //Active

    or status       =  '09' //Marked for Closing

    or status       =  '10' //To Be Closed

    or status       =  '11' //Closed at Bank

    or status       =  '15' //Closed in System

    or status       =  '28' //Opened at Bank

  )