I_BPAddlSuplrTelNmbrTP

@AbapCatalog.sqlViewName: 'IBPADDSTNTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BO view for Tel nos of MLTAS Suppliers'

@VDM.viewType: #TRANSACTIONAL
@ObjectModel.writeEnabled: true
@ObjectModel.createEnabled

@ObjectModel.deleteEnabled
@ObjectModel.updateEnabled
@Search.searchable: true
@ObjectModel.semanticKey: ['BusinessPartner', 'Supplier', 'AddressID', 'Person', 'OrdinalNumber' ]
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.writeDraftPersistence: 'BPADDSTN_D'
@ObjectModel.draftEnabled:true

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
define view I_BPAddlSuplrTelNmbrTP as select from I_BPTelephoneNumber as BPTelephoneNumber inner join I_BPMultipleAssignment as BPMultipleAssignment on BPTelephoneNumber.AddressID = BPMultipleAssignment.AddressNumber inner join I_Supplier as Supplier on BPMultipleAssignment.BPObjectID = Supplier.Supplier

  association [1..1] to I_BusinessPartnerTP as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [1..1] to I_BPAdditionalSupplierTP as _BPAdditionalSupplier on $projection.BusinessPartner = _BPAdditionalSupplier.BusinessPartner
                                                                         and $projection.Supplier = _BPAdditionalSupplier.Supplier 

                                                                         
{  
      key BPMultipleAssignment.BusinessPartner,
      key Supplier.Supplier as Supplier,
      key BPTelephoneNumber.AddressID, 
      key BPTelephoneNumber.Person, 
      key BPTelephoneNumber.OrdinalNumber,    
      BPTelephoneNumber.DestinationLocationCountry, 
      BPTelephoneNumber.IsDefaultPhoneNumber, 
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      BPTelephoneNumber.PhoneNumber, 
      BPTelephoneNumber.PhoneNumberExtension, 
      BPTelephoneNumber.InternationalPhoneNumber, 
      BPTelephoneNumber.PhoneNumberType,      
      Supplier.SupplierName,
      
       //    For field length increment

      Supplier.BPSupplierName,
      
      BPTelephoneNumber._AddressCommunicationRemark.CommunicationRemarkText as AddressCommunicationRemarkText,
//      cast('' as ad_remark2 ) as AddressCommunicationRemarkText,

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _BusinessPartner,      
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _BPAdditionalSupplier
      
}
where BPMultipleAssignment.IsStandardAssignment <> 'X' and BPMultipleAssignment.BPAssignmentCategory = 'SUPPL'