I_AugmentedPhysInvtryDocItem

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'IAUPIDOCITEM'
@EndUserText.label: 'Augmented Physical Inventory Doc Item'

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.private: false
@VDM.viewType: #COMPOSITE

define view I_AugmentedPhysInvtryDocItem
  as select from           I_PhysInvtryDocItem

  association [0..1] to I_AdjmtPostingMovementType  as _AdjmtPostingMovementType    on  $projection.PhysicalInventoryStockType = _AdjmtPostingMovementType.PhysicalInventoryStockType
                                                                                    and $projection.InventorySpecialStockType  = _AdjmtPostingMovementType.InventorySpecialStockType

  association [0..1] to I_GoodsMovementType         as _GoodsMovementType           on  $projection.GoodsMovementType = _GoodsMovementType.GoodsMovementType
    
{
      //Key

      @Semantics.calendar.year: true
  key FiscalYear,
  key PhysicalInventoryDocument,
  key PhysicalInventoryDocumentItem,

      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      @ObjectModel.foreignKey.association: '_StorageLocation'
      StorageLocation,
      @ObjectModel.foreignKey.association: '_Material'
      Material,           
      RealProductBatch, 
      Batch,
      ValuationType,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
      InventorySpecialStockType,
      @ObjectModel.foreignKey.association: '_PhysicalInventoryStockType'
      PhysicalInventoryStockType,
      @ObjectModel.foreignKey.association: '_SalesOrder'
      SalesOrder,
      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      SalesOrderItem,
      @ObjectModel.foreignKey.association: '_SalesOrderScheduleLine'
      ScheduleLine,
      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier,
      @ObjectModel.foreignKey.association: '_Customer'
      Customer,
      WBSElementInternalID,
      
      //Status

      PhysicalInventoryItemIsCounted,
      PhysInvtryDifferenceIsPosted,
      PhysInvtryItemIsRecounted,
      PhysInvtryItemIsDeleted,
      
      // Process Types

      CycleCountType,
      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      cast((case when Quantity > BookQtyBfrCountInMatlBaseUnit and PhysicalInventoryItemIsCounted = 'X'
         then  _AdjmtPostingMovementType.PhysInvtryIncreasingQtyMvtType
         else case when Quantity < BookQtyBfrCountInMatlBaseUnit and PhysicalInventoryItemIsCounted = 'X' 
              then  _AdjmtPostingMovementType.PhysInvtryDecreasingQtyMvtType
              else ''
              end    
      end) as pi_bwart preserving type)                          as GoodsMovementType,
      
      // Processing Data

      PhysicalInventoryLastCountDate,
      PostingDate,
      ReasonForPhysInvtryDifference,
      LastChangeDate,
      PhysInvtryDiffIsDistributed,

      @Semantics.currencyCode: true
      Currency,

      // References

      case when PhysInventoryReferenceNumber = '' 
        then 
          _PhysInvtryDocHeader.PhysInventoryReferenceNumber 
        else 
          PhysInventoryReferenceNumber
        end                                                      as PhysInventoryReferenceNumber,      
      MaterialDocumentYear,
      MaterialDocument,
      MaterialDocumentItem,
      PhysInvtryRecountDocument,

      // Material Types

      IsValueOnlyMaterial,
      IsHandledInAltvUnitOfMsr,
      @ObjectModel.foreignKey.association: '_ProductCategory'
      ProductCategory,
      @ObjectModel.foreignKey.association: '_CrossPlantConfigurableMatl'
      CrossPlantConfigurableMaterial,                         

      //Quantities

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @DefaultAggregation: #NONE
      BookQtyBfrCountInMatlBaseUnit,
      PhysicalInventoryItemIsZero,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @DefaultAggregation: #NONE
      Quantity,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_MaterialBaseUnit'
      MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'UnitOfEntry'
      @DefaultAggregation: #NONE
      QuantityInUnitOfEntry,
      cast ((Quantity - BookQtyBfrCountInMatlBaseUnit) as pi_item_diff_qty_i_base_unit preserving type ) as DifferenceQuantityInBaseUnit,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_UnitOfEntry'
      UnitOfEntry,
          
      //Amounts

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #NONE
      EnteredSlsAmtInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #NONE
      SlsPriceAmountInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #NONE
      PhysInvtryCtAmtInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #NONE
      BookQtyAmountInCoCodeCrcy,        
      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #NONE
      cast(( case when IsValueOnlyMaterial = ''
                  then case when Quantity < BookQtyBfrCountInMatlBaseUnit
                            then -DifferenceAmountInCoCodeCrcy
                            else DifferenceAmountInCoCodeCrcy
                       end
                   else case when EnteredSlsAmtInCoCodeCrcy < SlsPriceAmountInCoCodeCrcy
                             then -DifferenceAmountInCoCodeCrcy
                             else DifferenceAmountInCoCodeCrcy
                        end
              end)     as        pi_item_diff_value preserving type )                               as DifferenceAmountInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #MAX
      cast(DifferenceAmountInCoCodeCrcy as pi_item_max_diff_value preserving type )                 as MaxAbsDiffAmountInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #MIN
      cast(DifferenceAmountInCoCodeCrcy as pi_item_min_diff_value preserving type )                 as MinAbsDiffAmountInCoCodeCrcy,
      
      @Semantics.amount.currencyCode: 'Currency'
      cast((EnteredSlsAmtInCoCodeCrcy - SlsPriceAmountInCoCodeCrcy) as pi_item_diff_sls_prc_co_cry2 preserving type ) as DiffSlsPrcAmtInCoCodeCrcy,


      @DefaultAggregation: #SUM
      cast( 1 as pi_number_of_items)                                                                as NumberOfPhysInvtryItems,

      _WBSElement,
      _AdjmtPostingMovementType,
      _Material,
      _ProductPlant,
      _ProductStorageLocation,
      _CrossPlantConfigurableMatl,
      _MaterialBaseUnit,
      _UnitOfEntry,
      _Currency,
      _Supplier,
      _Customer,
      _SalesOrder,
      _SalesOrderItem,
      _SalesOrderScheduleLine,
      _Plant,
      _StorageLocation,
      _PhysInvtryDocHeader,
      _PhysicalInventoryStockType,
      _InventorySpecialStockType,
      _ProductCategory,
      _GoodsMovementType,
      
      @Consumption.hidden: true
      _SupplierCompanyByPlant,
      @Consumption.hidden: true
      _CustomerCompanyByPlant

}