I_AssetClass

@AbapCatalog: {sqlViewName: 'IFIASSETCL', preserveKey: true}
@Analytics: { dataCategory: #DIMENSION }
@EndUserText.label: 'Asset Class'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel: { sapObjectNodeType.name: 'FixedAssetClass',
                representativeKey: 'AssetClass',
                usageType.serviceQuality: #A,
                usageType.sizeCategory: #S,
                usageType.dataClass: #CUSTOMIZING,
                modelingPattern: #ANALYTICAL_DIMENSION,
                supportedCapabilities: [#ANALYTICAL_DIMENSION]
              }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: {ignorePropagatedAnnotations: true, allowExtensions:true}

define view I_AssetClass
  as select from P_AssetClass

  association [0..*] to I_AssetClassText           as _Text                     on $projection.AssetClass = _Text.AssetClass
  association [0..1] to I_AssetAcctDetermination   as _AssetAcctDetermination   on $projection.AssetAccountDetermination = _AssetAcctDetermination.AssetAccountDetermination
  association [0..1] to I_BusinessArea             as _BusinessArea             on $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_Plant                    as _Plant                    on $projection.Plant = _Plant.Plant
  association [0..1] to I_Country                  as _Country                  on $projection.AssetCountryOfOrigin = _Country.Country
  association [0..1] to I_Supplier                 as _Supplier                 on $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_FixedAssetFinDataCmpltns as _FixedAssetFinDataCmpltns on $projection.FixedAssetFinDataCmpltns = _FixedAssetFinDataCmpltns.FixedAssetFinDataCmpltns
  association [0..1] to I_FixedAssetPropertyType   as _FixedAssetPropertyType   on $projection.FixedAssetPropertyType = _FixedAssetPropertyType.FixedAssetPropertyType
  association [0..1] to I_PropertyClass            as _PropertyClass            on $projection.PropertyClass = _PropertyClass.PropertyClass
  association [0..1] to I_Group1AssetEvaluationKey as _Group1AssetEvaluationKey on $projection.Group1AssetEvaluationKey = _Group1AssetEvaluationKey.Group1AssetEvaluationKey
  association [0..1] to I_Group2AssetEvaluationKey as _Group2AssetEvaluationKey on $projection.Group2AssetEvaluationKey = _Group2AssetEvaluationKey.Group2AssetEvaluationKey
  association [0..1] to I_Group3AssetEvaluationKey as _Group3AssetEvaluationKey on $projection.Group3AssetEvaluationKey = _Group3AssetEvaluationKey.Group3AssetEvaluationKey
  association [0..1] to I_Group4AssetEvaluationKey as _Group4AssetEvaluationKey on $projection.Group4AssetEvaluationKey = _Group4AssetEvaluationKey.Group4AssetEvaluationKey
  association [0..1] to I_InvestmentReason         as _InvestmentReason         on $projection.InvestmentReason = _InvestmentReason.InvestmentReason
{
      @ObjectModel.text.association: '_Text'
  key AssetClass,

      @ObjectModel.foreignKey.association: '_AssetAcctDetermination'
      AssetAccountDetermination,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_BusinessArea'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } } ]
      BusinessArea,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      @VDM.lifecycle.status: #DEPRECATED
      CostCenter,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_FixedAssetFinDataCmpltns'
      FixedAssetFinDataCmpltns,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_Country'
      AssetCountryOfOrigin,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_Supplier'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_Supplier_VH', element: 'Supplier' } } ]
      Supplier,
      @VDM.lifecycle.status: #DEPRECATED
      FixedAssetGroup,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_FixedAssetPropertyType'
      FixedAssetPropertyType,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_PropertyClass'
      PropertyClass,
      @VDM.lifecycle.status: #DEPRECATED
      InvestmentSupportMeasure,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_Group1AssetEvaluationKey'
      Group1AssetEvaluationKey,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_Group2AssetEvaluationKey'
      Group2AssetEvaluationKey,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_Group3AssetEvaluationKey'
      Group3AssetEvaluationKey,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_Group4AssetEvaluationKey'
      Group4AssetEvaluationKey,
      @VDM.lifecycle.status: #DEPRECATED
      @ObjectModel.foreignKey.association: '_InvestmentReason'
      InvestmentReason,

      @Consumption.hidden: true
      AssetAuthorizationContext, //Needed for DCL


      //* Asscociations *//

      _Text,
      _AssetAcctDetermination,
      @VDM.lifecycle.status: #DEPRECATED
      _BusinessArea,
      @VDM.lifecycle.status: #DEPRECATED
      _Plant,
      @VDM.lifecycle.status: #DEPRECATED
      _Country,
      @VDM.lifecycle.status: #DEPRECATED
      _Supplier,
      @VDM.lifecycle.status: #DEPRECATED
      _FixedAssetFinDataCmpltns,
      @VDM.lifecycle.status: #DEPRECATED
      _FixedAssetPropertyType,
      @VDM.lifecycle.status: #DEPRECATED
      _PropertyClass,
      @VDM.lifecycle.status: #DEPRECATED
      _Group1AssetEvaluationKey,
      @VDM.lifecycle.status: #DEPRECATED
      _Group2AssetEvaluationKey,
      @VDM.lifecycle.status: #DEPRECATED
      _Group3AssetEvaluationKey,
      @VDM.lifecycle.status: #DEPRECATED
      _Group4AssetEvaluationKey,
      @VDM.lifecycle.status: #DEPRECATED
      _InvestmentReason
}