I_AllocReceiverKeyFieldTP

@AbapCatalog.sqlViewName: 'ALORCVRFIELDTP'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:#NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M

@EndUserText.label: 'Allocation Receiver Key Field TP'
@VDM.viewType: #TRANSACTIONAL
@ObjectModel:
{
  transactionalProcessingEnabled:true,
  writeDraftPersistence: 'ALORCVRFIELDTPD',
  semanticKey: ['AllocationType', 'AllocationCycle', 'AllocationCycleStartDate', 'AllocationCycleSegment', 'AllocDocumentSequenceNumber' ],
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true

//  entityChangeStateId: 'LastChangeTime'

}
define view I_AllocReceiverKeyFieldTP
  as select from I_AllocationKeyField
    inner join   I_AllocationContextType as Context on Context.AllocationType = I_AllocationKeyField.AllocationType

  association [0..*] to I_AllocRcvrRefKeyFldTP as _RcvrRefKeyFld on  $projection.AllocationType              = _RcvrRefKeyFld.AllocationType
                                                                 and $projection.AllocationCycle             = _RcvrRefKeyFld.AllocationCycle
                                                                 and $projection.AllocationCycleStartDate    = _RcvrRefKeyFld.AllocationCycleStartDate
                                                                 and $projection.AllocationCycleSegment      = _RcvrRefKeyFld.AllocationCycleSegment
                                                                 and $projection.AllocDocumentSequenceNumber = _RcvrRefKeyFld.AllocDocumentSequenceNumber

  association [1..1] to I_AllocationSegmentTP  as _Segment       on  $projection.AllocationType           = _Segment.AllocationType
                                                                 and $projection.AllocationCycle          = _Segment.AllocationCycle
                                                                 and $projection.AllocationCycleStartDate = _Segment.AllocationCycleStartDate
                                                                 and $projection.AllocationCycleSegment   = _Segment.AllocationCycleSegment

  association [1..1] to I_AllocationCycleTP    as _Cycle         on  $projection.AllocationType           = _Cycle.AllocationType
                                                                 and $projection.AllocationCycle          = _Cycle.AllocationCycle
                                                                 and $projection.AllocationCycleStartDate = _Cycle.AllocationCycleStartDate
{
  key I_AllocationKeyField.AllocationType,
  key AllocationCycle,
  key AllocationCycleStartDate,
  key AllocationCycleSegment,
  key AllocDocumentSequenceNumber,
      AllocationFieldName,
      AllocationSetName,
      AllocationFieldMinimumValue,
      AllocationFieldMaximumValue,
      AllocationSetId,
      AllocationSetType,
      @ObjectModel: {
               readOnly: true,
               virtualElement,
               virtualElementCalculatedBy: 'ABAP:CL_FCO_ALLOC_KEY_CDS_EXIT'
            }
      cast( '' as ltext )   as AllocationFieldText,
      
      AllocKeyFieldIsInitial,
      AllocKeyFieldIsAllValues,

      @ObjectModel.association.type: #TO_COMPOSITION_CHILD
      _RcvrRefKeyFld,
      @ObjectModel.association.type: #TO_COMPOSITION_PARENT
      _Segment,
      @ObjectModel.association.type: #TO_COMPOSITION_ROOT
      _Cycle
}
where
  AllocationSetType = '3'