I_ActiveCostElementWithDraft

@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
@EndUserText.label: 'Active Cost Element With Draft Info'
@Analytics.dataCategory: #DIMENSION
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IFIACOSTELMNT'
@ObjectModel.representativeKey: 'GLAccount'
@ObjectModel.usageType: {
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}

define view I_ActiveCostElementWithDraft
  as select from         I_CostElement                as ActiveDocument
  //Migrate to draft 2.0

  left outer to one join I_GLAcctDraft                as DraftDocument on  ActiveDocument.ChartOfAccounts = DraftDocument.ActiveChartOfAccounts
                                                                      and ActiveDocument.CostElement     = DraftDocument.ActiveGLAccount
                                                                      and DraftDocument.HasActiveEntity  = 'X'
  left outer join        I_DraftAdministrativeData    as DraftAdmin    on DraftDocument.GLAcctInChartOfAcctsDraftUUID = DraftAdmin.DraftUUID
  association [0..1] to  I_GLAccountInChartOfAccounts as _GLAccountInChartOfAccounts on  $projection.ChartOfAccounts = _GLAccountInChartOfAccounts.ChartOfAccounts
                                                                                    and $projection.GLAccount       = _GLAccountInChartOfAccounts.GLAccount
  association [0..1] to  I_CostElementCategory        as _CostElementCategory        on  $projection.CostElementCategory = _CostElementCategory.CostElementCategory
  association [0..*] to  I_GLAccountText              as _Text                       on  $projection.ChartOfAccounts = _Text.ChartOfAccounts
                                                                                    and $projection.GLAccount       = _Text.GLAccount
  association [0..1] to  I_UnitOfMeasure              as _UnitOfMeasure              on  $projection.UnitOfMeasure = _UnitOfMeasure.UnitOfMeasure
  association [0..1] to  I_ControllingArea            as _ControllingArea            on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to  I_ChartOfAccounts            as _ChartOfAccounts            on  $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
  association [0..1] to  I_GLAcctTxtInMaintLang       as _GLAcctTxtInMaintLang       on  $projection.ChartOfAccounts = _GLAcctTxtInMaintLang.ChartOfAccounts
                                                                                    and $projection.GLAccount       = _GLAcctTxtInMaintLang.GLAccount
{
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
  key ActiveDocument.ChartOfAccounts,
      @ObjectModel.foreignKey.association: '_ControllingArea'
  key ActiveDocument.ControllingArea,
  key ActiveDocument.GLAccount,
      ActiveDocument.ValidityStartDate,
      ActiveDocument.ValidityEndDate,
      @ObjectModel.mandatory: 'undefined'
      ActiveDocument.CostElementCategory,
      @ObjectModel.mandatory: 'undefined'
      ActiveDocument.ConsumptionQtyIsRecorded,
      @ObjectModel.mandatory: 'undefined'
      ActiveDocument.UnitOfMeasure,
      ActiveDocument.CreationDate,
      ActiveDocument.CreatedByUser,
      ActiveDocument.FunctionalArea,
      ActiveDocument.AcctAssignmentIsStatistical,
      @ObjectModel.readOnly: true
      cast( case _GLAccountInChartOfAccounts._GLAcctInChartOfAcctsProdn.GLAccountIsNotProdnRelevant
        when 'X' then 'X'
        else ' ' end as fins_glacct_not_needed ) as GLAccountIsNotProdnRelevant,
      @ObjectModel.readOnly: true
      _GLAccountInChartOfAccounts._GLAcctInChartOfAcctsStatus.GLAcctCOAImplementStatus as GLAcctCOAImplementStatus,
      @ObjectModel.readOnly: true
      _GLAccountInChartOfAccounts._GLAcctInChartOfAcctsStatus.GLAccountCOAIsDeliveredBySAP as GLAccountCOAIsDeliveredBySAP,
              
      DraftAdmin.DraftIsProcessedByMe,
      DraftAdmin.InProcessByUser,
      DraftAdmin.InProcessByUserDescription,
      cast( case
           when( DraftDocument.GLAcctInChartOfAcctsDraftUUID is null ) then ' '
              else 'X'
            end as sdraft_has_draft )                                         as HasDraftEntity,
      ActiveDocument.LastChangeDateTime, // ETag

      _GLAccountInChartOfAccounts.GLAccountType,

      /* Associations */
      _GLAccountInChartOfAccounts,
      _CostElementCategory,
      _Text,
      _UnitOfMeasure,
      _ControllingArea,
      _ChartOfAccounts,
      _GLAcctTxtInMaintLang
}