I_AcctgDocPaymentCardData

@AbapCatalog: {
    buffering.status: #NOT_ALLOWED,
    sqlViewName: 'IBSEGC'
}
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ClientHandling.algorithm : #SESSION_VARIABLE
@EndUserText.label: 'AcctgDoc: Data on Payment Card Payments'
@Metadata.allowExtensions:true
@ObjectModel: {
    representativeKey: 'AccountingDocument',
    usageType: {
        dataClass: #MIXED,
        serviceQuality: #C,
        sizeCategory: #XL
    }
}
@VDM: {
    viewType: #BASIC,
    private: false
}

define view I_AcctgDocPaymentCardData
  as select from bsegc
{
  key cast( bukrs as fis_bukrs preserving type )       as CompanyCode,
  key cast( belnr as farp_belnr_d preserving type )    as AccountingDocument,
  key cast( gjahr as fis_gjahr preserving type )       as FiscalYear,
  key cast( rfzei as fis_rfzei_cc preserving type )    as PaymentCardItem,
      ccins                                            as PaymentCardType,
      ccnum                                            as PaymentCardNumber,
      ccfol                                            as PaymentCardSequenceNumber,
      datab                                            as PaymentCardValidityStartDate,
      datbi                                            as PaymentCardValidityEndDate,
      ccname                                           as PaymentCardHolderName,
      cast( csour as farp_csour preserving type )      as PaymentCardEntryMode, // PaymentCardEntryModeTxt (text)

      autwr                                            as AuthorizedAmountInAuthznCrcy,
      ccwae                                            as AuthorizationCurrency,
      cast( settl as farp_settl preserving type )      as PaytCardSettlementIsCarriedOut,
      aunum                                            as AuthorizationByPaytSrvcPrvdr,
      autra                                            as AuthorizationByAcquirer,
      audat                                            as AuthorizationDate,
      autim                                            as AuthorizationTime,
      merch                                            as MerchantByClearingHouse,
      cast( locid as farp_locid_cc preserving type )   as PaytCardPointOfReceiptID,
      cast( trmid as farp_trmid preserving type )      as PaymentCardTerminal,
      cast( ccbtc as farp_ccbtc preserving type )      as PaymentCardPaymentSettlement,
      cast( cctyp as farp_cctyp preserving type )      as PaymentCardCategoryCode,
      //      ccard_guid,

      dp_token                                         as PaytCardByDigitalPaymentSrvc,
      cast( setra as farp_setra_cc preserving type )   as PaytCardClrgHsSettlmtRefNumber,
      rcavr                                            as PaytCardAddressVerificationSts, // PaytCardAddrVerificatStsName (text)

      cast( rcava as farp_rcava_cc preserving type )   as PaytCardAddrChkApprvlStsCode,   // PaytCardAddrChkApprvlStsTxt (text)

      cast( rcavz as farp_rcavz_cc preserving type )   as PaytCardAddrChkZipCodeStsCode,  // PaytCardAddrChkZipCodeStsTxt (text)

      rcrsp                                            as PaymentCardVerificationStatus,  // PaytCardVerificationStatusName (text)

      cast( rtext as farp_rtext_cc preserving type )   as PaytCardVerificationResult,
      cast( dp_rtext_long as farp_rtext_long preserving type ) as PaytCardVerificatDetResultText,
      cast( react as farp_react_cc preserving type )   as PaytCardSettlmtRsltRspCode,
      kunnr                                            as Customer,
      cast(dp_payid as farp_dp_payid preserving type ) as PaymentByPaymentServicePrvdr,
      dp_auth_rel_id                                   as PaymentCardAuthznRelationID,
      dp_advref                                        as PaymentAdviceReference,
      dp_l2l3_sent                                     as PaymentCardDataIsSent,
      dp_psp                                           as PaymentServiceProvider,
      dp_psp_transid                                   as TransactionByPaytSrvcPrvdr,
      dp_trans_id                                      as PaymentByDigitalPaymentService,
      dp_charge_trans_id                               as RfnddPaytByDgtlPaymentService
      //      opbel,

      //      _dataaging

}