I_ARLockBoxBatchItem

@EndUserText.label: 'Lockbox Batch Item Data'  
//@Analytics.dataCategory: #CUBE 

@VDM.viewType: #COMPOSITE 
@AccessControl.authorizationCheck: #NOT_REQUIRED 
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA') //Partner's Bank Account - archiving is possible

@AbapCatalog.sqlViewName: 'IARLOCKBOXITEM' 
@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.sizeCategory: #XL 
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED

define view I_ARLockBoxBatchItem 
     as select from P_ARLockBoxBatchItem  as item
   // select status description from fix values of the domain FAR_ASTAT

  left outer join dd07v            on dd07v.domvalue_l = item.LockboxBatchItmStatus
                                   and dd07v.domname = 'FAR_CHECT_ASTAT'
                                   and dd07v.ddlanguage = $session.system_language    
                                            
  association [0..1] to I_Currency    as _Currency    on _Currency.Currency   = $projection.Currency           
  
-- Association with Lockbox   
  association [1..1] to I_ARLockBoxBatch as _Header
                                          on  item.LockboxBatchInternalKey  = _Header.LockboxBatchInternalKey
                                          and item.LockboxBatch  = _Header.LockboxBatch
                                          
  association [0..1] to I_JournalEntry    as _JournalEntry     on  $projection.BankLedgerDocument      = _JournalEntry.AccountingDocument
                                                               and $projection.CompanyCode             = _JournalEntry.CompanyCode
                                                               and $projection.FiscalYear              = _JournalEntry.FiscalYear
                                                               
  association [0..1] to I_Arbsitmemolinewithorig as _MemoLine on  $projection.LockboxBatchInternalKey = _MemoLine.BankStatementShortID
                                                                   and $projection.LockboxBatchItem        = _MemoLine.BankStatementItem                                                             
{

   key  LockboxBatchInternalKey,   
   key  LockboxBatchItem,   
   key  LockboxBatch,
   ValueDate,
   @Semantics.currencyCode: true
   Currency,
   @DefaultAggregation: #NONE
   @Semantics.amount.currencyCode: 'Currency' 
   cast(AmountInTransactionCurrency   as farp_fwbtr)          as AmountInTransactionCurrency,
   cast (LockboxBatchItmStatus as far_chect_astat)            as LockboxBatchItmStatus,  
   cast(dd07v.ddtext as far_lb_stat_desc)                     as LockboxBatchItmStatusName,   
   IsCompleted,    
   cast(Cheque as farp_chect)                                 as Cheque,//until 02/2018 CustomerReferenceNumber was used here. By accident.                                                                         

   cast(PartnerBankCountry as farp_pabks)                     as PartnerBankCountry,
   cast(PartnerBank as farp_pablz)                            as PartnerBank,
   cast(PartnerBankAccount as farp_pakto)                     as PartnerBankAccount,
   BankLedgerDocument, 
   cast(PaymentAdviceAccount as kunnr)                        as Customer,
   cast(ApplicationLog as far_applog)                         as ApplicationLog,
   _MemoLine.MemoLine                                         as MemoLine,
   //not needed due to new string based persistence

   cast(MemoLine1  as farp_memo_line_1)                       as MemoLine1,    
   AssignmentReference,
   cast(PaymentExternalTransacType as farp_vorgc)             as PaymentExternalTransacType,
   cast(DocumentItemText as text50)                           as DocumentItemText,
   DocumentReferenceID,
   cast(PaymentManualTransacType as vgman_eb)                 as PaymentManualTransacType,
   cast(BankLedgerIsPosted as farp_vb1ok)                     as BankLedgerIsPosted,
   cast(SubledgerIsPostedSuccessfully as farp_vb2ok)          as SubledgerIsPostedSuccessfully,
   cast(LockboxSubledgerDocument as far_sdoc2)                as LockboxSubledgerDocument,
   CompanyCode,
   FiscalYear ,
   BankLedgerAcctgDocFiscalYear,
   SubledgerDocument,
   AdditionalInformation                                      as LockboxBatchItmAdditionalInfo,
   SubledgerAcctgDocFiscalYear, 
   PaymentAdvice,
   _Currency,
   _Header,
   _JournalEntry,
   SubledgerOnAccountDocument ,
   _Header.Lockbox,
  BankStatementItemDraftUUID,
  BankStatementInternalID,
  LockboxProcessingStatus,
  BankPostingDate,
  BankPostingKey,
  BankReference,
  BusinessArea,
  BusinessPartnerName,
  TreasuryContract,
  DaybookEntry,
  DunningBlockingReason,
  ExchangeRate,
  FeeAmountInTransactionCrcy,
  FeeAmountInOriginalCrcy,
  MemoLineIsChanged,
  AmountInOriginalCurrency,
  OriginalCurrency,
  OverdueChargeAmtInTransacCrcy,
  PartnerBankIBAN,
  PartnerBankSWIFTCode,
  PaymentAdviceAccount,
  PaymentAdviceAccountType,
  PaymentAdviceAccountTypeName,
  PaymentReference,
  PostingDate,
  PostingErrorStatus,
  ReferenceDocument,
  ReferenceDocumentType,
  BankStmntItemReprocessReason,
  ReturnReason,
  TreasuryContractType,
  ValueDateTime,
  MachineLrngBankStmntItemStatus,
  CostCenter,
  ProfitCenter,
  DebitCreditCode
}